将 Fortran 零长度数组传递给 C 的正确方法是什么？

Question

我有以下类型的子例程包装器将 Fortran 数组传递给ISO_C_BINDING-bound C 函数。

subroutine mysub( array )
  integer, dimension(:) :: array
  call f_mysub( size(array) , array(1) )
end subroutine

问题在于，如果数组的大小为 0，那么 array(1) 就会越界。处理这种情况的正确方法是什么？

一般来说，我无法避免通话，即使用if( size(array) > 0 )，因为通话可能对注册很重要，例如它实际上是一个类方法，与上面的签名自然不同，并且可以清除现有数组。

示例文件

C 例程是c_mysub.c。

#include <stdio.h>
void c_mysub( size_t* size, int* arr )
{
    printf("size=%d\n",*size);
    for(size_t i=0; i<*size; ++i)
    {
        printf("element %d=%d\n",i,arr[i]);
    }
}

主Fortran文件是mysub.f90

module mysub_I
interface
subroutine f_mysub( size, arr) BIND(C,name="c_mysub")
    use,intrinsic :: ISO_C_BINDING
    integer(C_SIZE_T) :: size
    integer(C_INT) :: arr
end subroutine
end interface
end module

module mysub_M
use mysub_I
contains

subroutine mysub( array )
  use ISO_C_BINDING
  integer, dimension(:) :: array
  call f_mysub( int(size(array),C_SIZE_T) , array(1) )
end subroutine

end module

program main
use mysub_M
integer, allocatable :: x(:)

allocate( x(7) )
x=1

call mysub( x )

deallocate( x )
allocate( x(0) )

call mysub( x )

end

使用 gcc -c c_mysub.c 编译 C 和使用 gfortran -fbounds-check c_mysub.o mysub.f90 编译 Fortran，当您运行代码时会出现以下错误，在 size=0 的第二次调用中犹豫不决。

size=7
0:1
1:1
2:1
3:1
4:1
5:1
6:1
At line 18 of file mysub.f90
Fortran runtime error: Index '1' of dimension 1 of array 'array' above upper bound of 0

在关闭边界检查的情况下进行编译的行为符合预期。

size=7
0:1
1:1
2:1
3:1
4:1
5:1
6:1
size=0

Answer 1

我看不出有任何理由将array(1) 作为实际参数传递。应该传递整个数组array。

  call f_mysub( size(array) , array )

并且必须更改接口以传递数组而不仅仅是标量

  integer(C_INT) :: arr(*)

如果array 不连续，则传递第一个元素（甚至是数组参数）很容易导致不正确的行为——这在理论上是可能的，因为它假定为形状虚拟参数（使用(:)）。

如果您传递整个数组和大小0，那么只需确保在 C 过程中实际上没有从指针中取消引用任何元素（如果写得好，应该已经是这种情况了）。