简化符号表达式

Question

我是 Lisp 新手，我需要一些帮助。 我需要简化下一个表达式： 从(+ (+ A B) C) 到(+ A B C) 从(- (- A B) C) 到(- A B C)。

如果你能帮我解决其中一个问题，我会明白我需要如何处理下一个问题。

非常感谢。

Answer 1

假设你有一个匹配这个模式的输入，(+ e1 ... en)，你想递归地把所有的e1简化为en，得到s1，...，sn，然后提取所有以+ 开头的si 将它们的参数上移一级，到您正在构建的简化表达式。

• 如果(and (consp e) (eq '+ (car e)))，则表达式e 匹配上述模式。
• 那么，所有ei 都由(cdr e) 列表给出。
• 考虑(+) 的情况，如何简化它？
• 要将函数f 应用于值列表，请调用(mapcar #'f list)。

• 要将列表拆分为两个列表，基于谓词p，您可以使用循环：

  (let ((sat nil) (unsat nil))
    (dolist (x list (values sat unsat))
      (if (funcall predicate x) 
          (push x sat) 
          (push x unsat))))
  

  有一种纯函数式的写法，你能搞定吗？

Answer 2

这是一个用 Racket 编写的简单简化器，它为+ 实现了一个相当愚蠢的简化器。请注意，这并不是什么严肃的事情：这只是我在思考这个问题时输入的内容。

这使用了 Racket 的模式匹配，可能以一种幼稚的方式来完成一些工作。

(define/match (simplify expression)
  ;; simplifier driver
  (((cons op args))
   ;; An operator with some arguments
   ;; Note that this assumes that the arguments to operators are always
   ;; expressions to simplify, so the recursive level can be here
   (simplify-op op (map simplify args)))
  ((expr)
   ;; anything else
   expr))

(define op-table (make-hash))

(define-syntax-rule (define-op-simplifier (op args) form ...)
  ;; Define a simplifier for op with arguments args
  (hash-set! op-table 'op (λ (args) form ...)))

(define (simplify-op op args)
  ;; Note the slightly arcane fallback: you need to wrap it in a thunk
  ;; so hash-ref does not try to call it.
  ((hash-ref op-table op (thunk (λ (args) (cons op args)))) args))

(define-op-simplifier (+ exprs)
  ;; Simplify (+ ...) by flattening + in its arguments
  (let loop ([ftail exprs]
             [results '()])
    (if (null? ftail)
        `(+ ,@(reverse results))
        (loop (rest ftail)
              (match (first ftail)
                [(cons '+ addends)
                 (append (reverse addends) results)]
                [expr (cons expr results)])))))

可能比这更具侵略性。例如，我们可以合并文字数字的运行，因此我们可以将(+ 1 2 3 a 4) 简化为 (+ 6 a 4)（请注意，通常将其进一步简化为 (+ 10 a) 是不安全的，除非所有算术都是精确的）。这是一个为+ 和* 合并的函数：

(define (coalesce-literal-numbers f elts)
  ;; coalesce runs of literal numbers for an operator f.
  ;; This relies on the fact that (f) returns a good identity for f
  ;; (so in particular it returns an exact number).  Thisis true for Racket
  ;; and CL and I think any Lisp worth its salt.
  ;;
  ;; Note that it's important here that (eqv? 1 1.0) is false.
  ;;;
  (define id (f))
  (let loop ([tail elts]
             [accum id]
             [results '()])
    (cond [(null? tail)
           (if (not (eqv? accum id))
               (reverse (cons accum results))
               (reverse results))]
          [(number? (first tail))
           (loop (rest tail)
                 (f accum (first tail))
                 results)]
          [(eqv? accum id)
           (loop (rest tail)
                 accum
                 (cons (first tail) results))]
          [else
           (loop (rest tail)
                 id
                 (list* (first tail) accum results))])))

这里是 + 的一个修改过的简化器，它使用了这个。除了合并之外，它还注意到 (+ x) 可以简化为 x。

(define-op-simplifier (+ exprs)
  ;; Simplify (+ ...) by flattening + in its arguments
  (let loop ([ftail exprs]
             [results '()])
    (if (null? ftail)
        (let ([coalesced (coalesce-literal-numbers + (reverse results))])
          (match coalesced
            [(list something)
             something]
            [exprs
             `(+ ,@exprs)]))
        (loop (rest ftail)
              (match (first ftail)
                [(cons '+ addends)
                 (append (reverse addends) results)]
                [expr (cons expr results)])))))

以下是使用此增强型简化器的示例：

> (simplify 'a)
'a
> (simplify 1)
1
> (simplify '(+ 1 a))
'(+ 1 a)
> (simplify '(+ a (+ b c)))
'(+ a b c)
> (simplify '(+ 1 (+ 3 c) 4))
'(+ 4 c 4)
> (simplify '(+ 1 2 3))
6

为了更有价值，您可以注意到* 的简化器实际上是相同的，并将其更改为：

(define (simplify-arith-op op fn exprs)
  (let loop ([ftail exprs]
             [results '()])
    (if (null? ftail)
        (let ([coalesced (coalesce-literal-numbers fn (reverse results))])
          (match coalesced
            [(list something)
             something]
            ['()
             (fn)]
            [exprs
             `(,op ,@exprs)]))
        (loop (rest ftail)
              (match (first ftail)
                [(cons the-op addends)
                 #:when (eqv? the-op op)
                 (append (reverse addends) results)]
                [expr (cons expr results)])))))

(define-op-simplifier (+ exprs)
  (simplify-arith-op '+ + exprs))

(define-op-simplifier (* exprs)
  (simplify-arith-op '* * exprs))

现在

(simplify '(+ a (* 1 2 (+ 4 5)) (* 3 4) 6 (* b)))
'(+ a 36 b)

相当整洁。

您可以走得更远，例如，当合并运算符的数字时，您可以简单地省略该运算符的身份序列：(* 1 1 a 1 1 b) 可以简化为(* a b)，而不是(* 1 a 1 b)。这样做似乎很愚蠢：谁会写这样的表达式，但在简化复杂的表达式时很容易出现。

此代码的详细版本有一个gist。它可能仍然是错误的。