如何在枫树中绘制二阶微分方程的解答案

【问题标题】：How to plot the solution to a second order differential equation in maple如何在枫树中绘制二阶微分方程的解
【发布时间】：2021-03-09 21:53:20
【问题描述】：

我的代码附在图片中。如何将解 y(x) 绘制为 x 的函数？这个 BVP y(x) 的解由命令 dsolve({de, ics}) 给出 enter image description here

with(DEtools);

      w := 20
      t := 5
      L := 200
      Base_TD := 0
      End_TD := 100
      x0 := 100
      K := 350*10^(-6)
      h := 850*10^(-12)
      de := diff(y(x), x, x) = 2*h*(w + t)*y(x)/(K*w*t) - (x - x0)^2
      dsolve(de)
      ics := y(0) = Base_TD, D(y)(100) = -h*End_TD/K
      dsolve({de, ics})

【问题讨论】：

没有人应该重新输入您的所有代码，并且仅发布代码图像是不体贴的。您应该将代码转换为一维纯文本符号并将其编辑到您的问题中（作为引用文本）。
@acer 我添加了更多信息，希望对您有所帮助！

标签： plot differential-equations maple

【解决方案1】：

你可以精确地或数字地解决这个问题。

他们的情节非常吻合。

restart;
w := 20: t := 5: L := 200:
Base_TD := 0: End_TD := 100: x0 := 100:
K := 350*10^(-6): h := 850*10^(-12):

de := diff(y(x), x, x)
      = 2*h*(w + t)*y(x)/(K*w*t)
        - (x - x0)^2:

ics := y(0) = Base_TD,
       D(y)(100) = -h*End_TD/K:

精确求解，然后构造图，

exactsol := dsolve({de, ics}):

PE := plot(rhs(exactsol), x=0..100):

数值求解（即生成一个程序，根据需要在时间点进行数值求解），然后构建绘图，

numericsol := dsolve({de, ics}, numeric):

PN := plots:-odeplot(numericsol,[x,y(x)],
                     x=0..100,
                     thickness=5,color=green):

将两者放在一起以进行比较，

plots:-display(PN,PE);

检查第二个边界条件，

evalf(ics);
numericsol(100);
plots:-odeplot(numericsol,[x,diff(y(x),x)],
               x=90 .. 100,
               thickness=5,color=green);

【讨论】：

如果它完全回答了你的问题，那么你可能会考虑“接受”它（绿色勾号）。