Val 过程是否使用 DecimalSeparator？

Question

StrToFloat 使用格式设置的DecimalSeparator。

似乎Val 只接受包含. 作为小数分隔符的字符串。

从_ValExt（Val 调用）中的 ASM 代码看来，它没有使用 DecimalSeparator。

我可以安全地相信Val 接受以. 作为小数分隔符的实数字符串这一事实吗？

Answer 1

Val 是古老的、低级的并且使用起来有点棘手。我不建议在用户代码中使用它。而是使用其他例程来扫描值，例如 StrToFloat 等。如果您将 StrToFloat 与 TFormatSettings.Invariant 一起使用，则可以确保将点 ('.') 作为小数分隔符。

看看下面的一段测试代码。在我的德语系统上，小数点分隔符是逗号。所以我尝试了以下方法：

procedure Test;
var
  E: Extended;
  S: Single;
  I: Integer;
  Code: Integer;
begin

  Val('1.234', E, Code);
  if Code = 0 then
    Writeln('1.234 Extended: ', E)
  else
    Writeln('1.234 Extended: Error, code = ', Code);

  Val('1,234', E, Code);
  if Code = 0 then
    Writeln('1,234 Extended: ', E)
  else
    Writeln('1,234 Extended: Error, code = ', Code);

  Val('1.234', S, Code);
  if Code = 0 then
    Writeln('1.234 Single: ', S)
  else
    Writeln('1.234 Single: Error, code = ', Code);

  Val('1234', I, Code);
  if Code = 0 then
    Writeln('Integer: ', I)
  else
    Writeln('Integer: Error, code = ', Code);

end;

输出是：

1.234 Extended:  1.23400000000000E+0000
1,234 Extended: Error, code = 2
1.234 Single:  1.23399996757507E+0000
Integer: 1234

这清楚地表明Val 不使用系统定义的小数分隔符，而只接受不变的小数分隔符，即'.'。 System.Val 的文档在这里有点误导，IMO。

更新

似乎我在代码的“单个部分”中使用了 E 而不是 S。显然，如果您传递Single，您也会得到正确的值，所以我猜编译器（它知道传递了什么）以某种方式将此信息传递给内部例程。

查看CPU窗口可以看到，如果传入一个浮点类型，则调用System.@ValExt，它返回FPU栈顶的值（ST(0)）。然后编译器添加适当的代码来存储该值（FSTP TBYTE、FSTP QWORD 或 FSTP DWORD 分别用于 Extended、Double 和 Single）。

类似地，对于整型变量（最多 32 位），调用 System.@ValLong，它在 EAX 中返回一个 Integer，并添加适当的代码以存储正确大小的值编译器。对于 64 位整数，调用@ValInt64，返回EDX:EAX 中的值。

FWIW，它还表明 Writeln 不使用系统定义的小数分隔符。