带有返回指针类型的模拟函数的 EInvalidCast

Question

我编写了一个接口来包装 Windows 线程池 API，其中许多函数返回普通的 Pointer 类型。

现在我正在编写测试并想使用 delphi-mocks framework 来模拟该包装器接口。

问题在于TMock 设置接口采用TValue 对象来指定模拟函数的默认返回值，而我无法从可用的TValue 函数中看到如何正确执行此操作的方法。虽然我已经看到 ekPointer 是一个有效的 TTypeKind 值。

当调用模拟函数时，我从相应的 RTTI 调用中收到 EInvalidCast 异常。
当 RTTI 调用尝试从隐式 TValue 对象转换返回类型值时，就会发生这种情况。

我的代码大致是这样的¹：

type
    PTP_POOL = Pointer;
    PTP_CLEANUP_GROUP = Pointer;

    IThreadPoolApi = interface(IInterface)
        {...}
        function CreateThreadPool() : PTP_POOL;
        function CreateThreadpoolCleanupGroup() : PTP_CLEANUP_GROUP;
        {...}
    end;

被测类

type
    TThreadPool = class(TInterfacedObject, IThreadPool)
        FTPApi : IThreadPoolApi;
        FPTPPool : PTP_POOL;
        FPTPCleanupGroup : PTP_CLEANUP_GROUP;
        {...}
    public
        constructor Create(iapi : IThreadPoolApi);
    end;

implementation
constructor TThreadPool.Create(iapi : IThreadPoolApi);
begin
    inherited Create();
    FTPApi := iapi;

    {**** Here I get a EInvalidCast exception when mocking the interface ****}
    FPTPPool := FTPApi.CreateThreadPool();
    if(not assigned(FPTPPool)) then
    begin
        {Raise exception}
        raise EThreadPoolError('Cannot create TP thread pool');
    end;

    {**** This case should be tested ****}
    FPTPCleanupGroup := FTPApi.CreateThreadpoolCleanupGroup();
    if(not assigned(FPTPPool)) then
    begin
         {Raise exception}
         raise EThreadPoolError('Cannot create TP cleanup group');
    end;

    {...}
end;

和测试的东西

procedure ThreadPoolTest.TestFail_CreateThreadpoolCleanupGroup();
var
   apiMock : TMock<IThreadPoolApi>;
   testproc : TTestLocalMethod;
begin
   apiMock := TMock<IThreadPoolApi>Create();
   {**** Needed to reach the call of CreateThreadpoolCleanupGroup
    but EInvalidCast is raised ****}
   apiMock.Setup.WillReturnDefault('CreateThreadPool',PTP_POOL($FFFFFFFF));
   {**** The case to be tested ****}
   apiMock.Setup.WillExecute('CreateThreadpoolCleanupGroup',
       function (const args : TArray<TValue>; const ReturnType : TRttiType) 
       : TValue
       begin
           result := nil;
       end);

    testproc := 
       procedure() 
       var
           threadpool : IThreadPool;
       begin
           threadpool := TThreadPool.Create(apiMock);
       end;
    DUnitX.Assert.WillRaise(testproc,EThreadPoolError,
                            'Cannot create TP cleanup group');
end;

TL;DR;

所以问题是：
我需要做什么才能正确创建 TValue 以包含 PTP_POOL 指针类型？

---

¹⁾_{设置MCVE的代码有点多，所以我在这里画了个草图给你背景，看{**** highlighted comments ****}}

Answer 1

将原始指针分配给TValue 时，使用TValue.From<T>() 方法，例如：

TValue.From<PTP_POOL>(nil);

或者，如果你想返回一个文字值：

TValue.From<PTP_POOL>(PTP_POOL(value));

TValue 没有对原始指针的隐式转换，但它对TObject 和TClass 指针有隐式转换。

如果你将一个无类型的 nil 指针直接分配给TValue，它会调用TValue.Implicit(TObject)，它会在传递一个 nil 指针时返回 TValue.Empty 属性。

如果将类型化的非TObject 指针直接分配给TValue，它会调用TValue.Implicit(TClass)，如果指针为nil，则返回TValue.Empty，否则返回TClass 类型的TClass指针的值，即使它实际上并未指向有效的类类型。

如果你传递一个指向TValue.From<T>()的指针，它会返回一个T类型的TValue和指针的值，即使它是nil。

这种差异很微妙，但非常重要。

Answer 2

我需要做什么才能正确创建 TValue 以包含 PTP_POOL 指针类型？

看起来@Remy 已经在their comment 中回答了我的问题。

要将指针值包含在 TValue 实例中，必须使用通用 TValue.From<T>() 函数创建它：

apiMock.Setup.WillReturnDefault('CreateThreadPool',
                                TValue.From<PTP_POOL>(PTP_POOL($FFFFFFFF)));

还有一点选角。