在 Haskell 中使用 Numeric.AD 时如何正确匹配类型？

Question

我正在尝试使用 ad 包实现 Newton–Raphson 寻根算法，但我无法正确匹配函数类型。我知道有a proper answer to a similar question，这个是广告主自己回答的，但是从1.0.6版本（当前版本是4.3.4）开始，包已经发生了很大的变化。

当我迭代它时，第一个最小示例编译并工作：

import Numeric.AD
import Numeric.AD.Internal.Forward

g :: Fractional a => a -> a
g x = - x + 2

g' :: Fractional a => a -> a
g' x = diff g x

newtonG :: Fractional a => a -> a
newtonG x = x - (g x) / (g' x)

但是如果我尝试抽象函数，像这样：

import Numeric.AD
import Numeric.AD.Internal.Forward

g :: Fractional a => a -> a
g x = - x + 2

newton :: Fractional a => (a -> a) -> a -> a
newton f x = x - (f x) / (diff f x)

GHC 返回以下错误：

fsolve.hs:8:32: error:
    * Couldn't match type `a' with `AD s (Forward a)'
      `a' is a rigid type variable bound by
        the type signature for:
          newton :: forall a. Fractional a => (a -> a) -> a -> a
        at fsolve.hs:7:11
      Expected type: AD s (Forward a) -> AD s (Forward a)
        Actual type: a -> a
    * In the first argument of `diff', namely `f'
      In the second argument of `(/)', namely `(diff f x)'
      In the second argument of `(-)', namely `(f x) / (diff f x)'
    * Relevant bindings include
        x :: a (bound at fsolve.hs:8:10)
        f :: a -> a (bound at fsolve.hs:8:8)
        newton :: (a -> a) -> a -> a (bound at fsolve.hs:8:1)

如果我使用Numeric.AD.Rank1.Forward 而不是Numeric.AD，编译器会说它不能匹配a 和Forward a，而不是a 和AD s (Forward a)。我还尝试了几种从x 创建双号码的方法，将其传递给f，例如snd . unbundle . f $ bundle x 1，但它只有在我使用它创建一个新的g' x 时才有效，就像在第一种情况下一样。在newton 中使用它也不起作用。

在Numeric.AD，diff :: Num a => (forall s. AD s (Forward a) -> AD s (Forward a)) -> a -> a。在Numeric.AD.Rank1.Forward 中，它是diff :: Num a => (Forward a -> Forward a) -> a -> a。那么为什么他们在第一种情况下接受a -> a 类型的函数，而在第二种情况下不接受呢？除了使用多态函数之外，在创建与Numeric.AD 一起使用的函数时，我是否应该特别注意？最后，我应该如何更改我的代码以使其工作？我知道包already has a function to find roots，但我还不想使用（因为我还在学习Haskell），并且查看文档试图解决这个问题，感觉就像在兜圈子。

Answer 1

观察你的函数：

newton :: Fractional a => (a -> a) -> a -> a
newton f x = x - (f x) / (diff f x)

在两个地方使用函数参数f。首先， 子表达式f x 使用f 类型为：

f :: Fractional a => a -> a

第二，由于diff的使用，子表达式diff f x使用f的类型：

f :: forall s a. Fractional a => AD s (Forward a) -> AD s (Forward a)

你得到的错误信息是类型系统观察到这些 是不能统一的不同类型。

解决方法是显式量化newton的函数参数 适用于满足适当数字类型类约束的所有类型。这需要RankNTypes 语言扩展：

{-# LANGUAGE RankNTypes #-}

newton
  :: Fractional a
  => (forall b. Fractional b => b -> b)
  -> a
  -> a
newton f x = x - (f x) / (diff f x)