匹配 Haskell 类型类中的类型

Question

我不知道如何准确地表达这个，所以如果有人有一个好名字，请告诉我。

我正在尝试编写一个名为Matchable 的类型类。这个想法是我拥有的几种不同类型的正则表达式（RegExp a、ComplexRegex a）应该能够匹配输入。

所以我尝试了这个：

class Matchable a where
  --   regex, input, success
  match :: a -> b -> Bool

但我真正想要的是用类型构造函数变量或其他东西解构类型类中的构造函数：

class Matchable a where
  --   regex, input, success
  match :: (B a) -> [a] -> Bool

这样我就可以在String 上匹配RegExp Char 和ComplexRegex Char。有没有办法做到这一点？谢谢。

Answer 1

为了简单起见，为什么不把Matchable 的类变量设置成* -> * 呢？ （参见Functor、Applicative、Monad、Foldable、Traversable 了解其他更高年级课程的示例）。

class Matchable b where
  --   regex, input, success
  match :: b a -> [a] -> Bool

instance Matchable ComplexRegex where
  -- match :: ComplexRegex a -> [a] -> Bool
  match = error "unimplemented"

instance Matchable RegExp where
  -- match :: RegExp a -> [a] -> Bool
  match = error "unimplemented"

然后，您可以将String ~ [Char] 与ComplexRegex Char 或RegExp Char 匹配。

Answer 2

作为 Alec 解决方案的替代方案，您可以使用 associated types。这允许没有类型* -> * 的类型，但如果没有必要，我会选择更简单的解决方案。例如。想象一下，除了RegExp a 和ComplexRegex a，你还有StringRegex 没有参数化，或者你只能为ComplexRegex Char 实现match 而不是ComplexRegex a：

class Matchable b where
  type Target b :: *
  --   regex, input, success
  match :: b -> [Target b] -> Bool

instance Eq a => Matchable (ComplexRegex a) where
  type Target (ComplexRegex a) = a
  -- match :: ComplexRegex a -> [a] -> Bool
  match = error "unimplemented"

instance Matchable StringRegex where
  type Target StringRegex = Char
  -- match :: StringRegex -> [Char] -> Bool
  match = error "unimplemented"

-- requires FlexibleInstances
instance Matchable (ComplexRegex Char) where
  type Target (ComplexRegex Char) = Char
  -- match :: ComplexRegex Char -> [Char] -> Bool
  match = error "unimplemented"

另一个区别是您的实例可以确保Eq (Target b)，而不是将其放入match 的类型中（您也可以将其设为要求：class Eq (Target b) => Matchable b where ...）。

Answer 3

您可能正在寻找更高种类的类型。如果您只对Char 和String 感兴趣并且函数的行为仅取决于它是RegExp 还是ComplexRegex，那么您可以定义下一个类型类：

class Matchable r where
  --   regex, input, success
  match :: r Char -> String -> Bool

这里r 是类型变量，类型为* -> *。简单来说，它是一个不完全类型。喜欢Maybe。你的函数不能有Maybe -> Int 类型，因为Maybe 是不完整类型，但Maybe Bool 是完整类型。与正则表达式类似：RegExp 和 ComplexRegex 都是不完整类型。感谢 Haskell 到达类型系统，您的函数也可以在不完整类型上进行参数化。所以后面在定义实例的时候，会按照下面的方式来写：

instance Matchable RegExp where
   ... -- implementation for RegExp goes here

instance Matchable ComplexRegex where
   ... -- implementation for CompltexRegex goes here

在明确指定函数类型和类型类型时，您会发现 -XKindSignatures 和 -XInstanceSigs 语言扩展很有帮助。