将函数与 Haskell 中的类型相关联

Question

假设你有一个序列化器/反序列化器类型类

class SerDes a where
    ser :: a -> ByteString
    des :: ByteString -> a

事实证明，为每种类型 a 提供一个特殊的辅助函数至关重要，例如

compress :: ByteString -> ByteString     -- actually varies with the original type

我将compress 视为一个函数，我想将它与每个a 关联，即SerDes。 （“关联”这个词可能是一个糟糕的选择，这也是互联网搜索没有结果的原因。）

这个例子并不像看起来那么做作，例如当decompress 是一个可选的 串行器/解串器的功能。 （是的，助手可以通过增加来避免 ser 带有控制压缩的开关 ser:: a -> Bool -> ByteString，或者更好地使用 Config 记录。但让我们坚持这个例子。）

这样做的一种方法是一个“虚拟”类，一个单例：

data For a = For

那么这将起作用：

class SerDes a where
    ser      :: a -> ByteString
    des      :: ByteString -> a
    compress :: For a -> ByteString -> ByteString

compress 的 a 将被实例化为

compress (For :: For MyType) input = ...

另一种有点不寻常的方法是将所有功能都粘贴到记录中。

data SerDes a = SerDes { ser      :: a -> ByteString
                       , des      :: ByteString -> a
                       , compress :: ByteString -> ByteString 
                       }

还有其他方法可以将compress 函数与a 类型“关联”吗？

Answer 1

您的 For a 类型在库中称为 Proxy a。

import Data.Proxy

class SerDes a where
    ser      :: a -> ByteString
    des      :: ByteString -> a
    compress :: Proxy a -> ByteString -> ByteString

有时这被概括为一个通用的proxy 类型变量。

class SerDes a where
    ser      :: a -> ByteString
    des      :: ByteString -> a
    compress :: proxy a -> ByteString -> ByteString

---

还有另一个选项，类似于代理。可以使用Tagged 将a 添加到结果类型，而不是强制将a 添加到参数中：

import Data.Tagged

class SerDes a where
    ser      :: a -> ByteString
    des      :: ByteString -> a
    compress :: ByteString -> Tagged a ByteString

这需要用作unTagged (compress someByteString :: Tagged T ByteString) 来告诉编译器我们想要T 的compress 函数。

---

就个人而言，我不喜欢代理和标签。过去当 GHC 不允许使用其他更简单的解决方案时需要它们，但现在不应再使用它们。

现代方法是打开无害的扩展 AllowAmbiguousTypes 和 TypeApplications 并简单地编写你想要的类

class SerDes a where
    ser      :: a -> ByteString
    des      :: ByteString -> a
    compress :: ByteString -> ByteString

在这种方法中，我们需要使用较短的compress @T someByteString，而不是调用compress (Proxy :: Proxy T) someByteString，我们明确地“传递我们想要的类型a”（在这种情况下为T），所以选择想要的compress.

完整示例：

{-# LANGUAGE AllowAmbiguousTypes, TypeApplications, OverloadedStrings #-}

import Data.ByteString as BS

class SerDes a where
    ser      :: a -> ByteString
    des      :: ByteString -> a
    compress :: ByteString -> ByteString

-- bogus implementation to show everything type checks
instance SerDes Int where
   ser _ = "int"
   des _ = 42
   compress bs = BS.tail bs

-- bogus implementation to show everything type checks
instance SerDes Bool where
   ser _ = "bool"
   des _ = True
   compress bs = bs <> bs

main :: IO ()
main = BS.putStrLn (compress @Int "hello" <> compress @Bool "world")
-- output: elloworldworld