部分应用函数类型 (a ->) 作为 Haskell 中的 Functor 实例

Question

我正在阅读“Haskell 编程”一书（第二版），偶然发现了练习 2，第 12 章，第 2 部分：

instance Functor ((->) a) where
  fmap = TODO

答案在哪里：

instance Functor ((->) a) where
  fmap = (.)

这让我摸不着头脑。我想这在直观层面上对我来说确实有意义（部分应用函数类型 a -> 是函子，而组合是它的 fmap），但我认为一些很好的例子会巩固我对练习的理解。

我想出了这两个：

main = do
    putStrLn . show $ (fmap (+1) (*2)) (5 :: Int)
    putStrLn . show $ (fmap (show) (+1)) 3

我的例子是否正确地说明了这个练习？

fmap 给定两个参数：

• 部分应用函数（函数）
• 另一个部分应用的函数（函子）

---

更新

fmap 给出两个参数：

• 函数（函数）
• 另一个函数（函子）

---

对我来说只是看起来很奇怪，我不确定我的概念是否正确。

我在 SO 上看到了一些类似的问题（例如 this one），其中 this one 几乎是我正在寻找的东西，但并不完全是（我只是在寻找函子的例子，没有别的 - 没有应用程序和没有单子）。

Answer 1

实际上没有什么比这更多的了，对于函子f，fmap 的实现（已知对于任何可能的f 最多有一个实现）必须具有类型(a -> b) -> f a -> f b，并满足两个函子定律：

fmap id = id
fmap (g . h) = fmap g . fmap h

当f 是类型构造函数(->) r - 即当f a 表示r -> a - 那么所需的类型签名是：

(a -> b) -> (r -> a) -> (r -> b)

（最后一对括号是不必要的，但我把它们留在里面是因为它使“模式”更容易看到），很容易看到正是(.) 运算符的签名。

至于这两条定律，很明显，当您写下它们所说的内容时，它们必须遵守。我将通过详细写出所有内容来证明它们：

fmap id = (.) id
        = \g -> id . g
        = \g -> (\a -> id (g a))
        = \g -> (\a -> g a)
        = \g -> g
        = id

和

fmap (g . h) = (.) (g . h)
             = \g1 -> (g . h) . g1
             = \g1 -> \a -> ((g . h) . g1) a
             = \g1 -> \a -> g (h (g1 a))

(fmap g) . (fmap h) = ((.) g) . ((.) h)
                    = \g1 -> ((.) g) (h . g1)
                    = \g1 -> g . h . g1
                    = \g1 -> \a -> g (h (g1 a))

所以这些也是一样的。

（不要太担心最后的推导 - 通常这些事情似乎很难遵循如何从一行到下一行的逻辑，即使这里它们基本上都使用组合的定义。这实际上只是表达了函数组合是关联的显而易见的众所周知的事实。无论如何，这是一个普遍的结果，除了我相信某些病理类型，如果满足第一个函子定律，那么第二个总是自动满足。）

重要的是：当f 被定义为f a = r -> a 时，组合运算符具有与fmap 相同的类型，并且满足两个函子定律 - 因此组合是一个合法的定义（并且 只有这样的定义）fmap 为f 创建一个Functor 实例。真的没有什么比这更重要的了，至少在形式上是这样。