Word VBA宏注释掉嵌套括号

Question

我有一个宏如下：

Sub CommentOutParenthsLocal()
'
' CommentBubble Macro
'
'
Dim myRange As Range
Set myRange = Selection.Range
Set oScope = myRange.Duplicate

searchText = "\(*\)"

With myRange.Find
    .MatchWildcards = True
    Do While .Execute(findText:=searchText, Forward:=True) = True
        If myRange.InRange(oScope) Then
            If Len(myRange.Text) > 4 Then
                ActiveDocument.Comments.Add myRange, myRange.Text
                myRange.Text = ""
            End If
        Else
            Exit Do
        End If
    Loop
 End With
End Sub

但是，如果我有嵌套括号，例如This is my (nested parenthesis (document ) in full)，这将不起作用

它将匹配第一个右括号而不是最外面的括号。有没有办法写一个匹配的正则表达式？

Answer 1

试试：

Sub Demo()
Application.ScreenUpdating = False
Dim Rng As Range
With Selection
  Set Rng = .Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "\([!\(]@\)"
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    .MatchWildcards = True
    .Execute
  End With
  Do While .Find.Found
    If Not .InRange(Rng) Then Exit Do
    If Len(.Text) > 4 Then
      .Comments.Add .Range, .Text
      .Text = ""
    End If
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
Application.ScreenUpdating = True
End Sub

Answer 2

作为建议，请尝试在每个模块/类/表单的开头使用 Option Explicit。这将阻止您使用尚未声明的变量。

下面的代码会减少

This is my (nested parenthesis (document ) in full)

到

This is my

与

(nested parenthesis (document ) in full)

作为评论添加。

Option Explicit

Sub CommentOutParenthsLocal()
'
' CommentBubble Macro
'
'
Dim myRange As Range
Set myRange = Selection.Range

Dim oScope As Word.Range
Set oScope = myRange.Duplicate

Dim searchtext As String
searchtext = "\(*\)"

    With myRange.Find

        .MatchWildcards = True

        Do While .Execute(findText:=searchtext, Forward:=True) = True

            myRange.Select

            If myRange.InRange(oScope) Then

                Dim myCount As Long
                Dim myText As String
                myText = myRange.Text
                myCount = Len(myText) - Len(Replace(myText, "(", vbNullString)) - 1

                Do Until myCount = 0

                    myRange.MoveEndUntil cset:=")"
                    myRange.MoveEnd Count:=1
                    myCount = myCount - 1

                Loop

                If Len(myRange.Text) > 4 Then

                    ActiveDocument.Comments.Add myRange, myRange.Text
                    myRange.Text = ""

                End If
            Else

                Exit Do

            End If
            myRange.Start = myRange.End + 1
            myRange.End = oScope.End

        Loop

     End With

End Sub