Prolog 从集合中获得最大收益

Question

这是一个简单的问题。

has(steve, 5).
has(mark, 6).
has(craig, 4).

在 Prolog 中你如何知道谁拥有最多？

我试过has(Who, Max) 但这没有帮助。这里有可以用的算子吗？

谢谢。

Answer 1

?- has(U,S),\+((has(V,T),T>S)).
U = mark,
S = 6 ;
false.

前缀运算符\+ 读作not。由于我们必须反证的是由中缀运算符, 表示的连词，因此需要使用双括号。

您应该知道，在使用它时，它是一种受限的否定形式，即所谓的negation as failure，由隐含在 Prolog 语义中的closed world assumption 实现。 p>

或者，完全相同

max(U,S) :- has(U,S),notanybetterthan(S).

notanybetterthan(S) :- has(_,T),T>S,!,fail.
notanybetterthan(_).

或

max(U,S) :- has(U,S),\+anybetterthan(S).

anybetterthan(S) :- has(_,T),T>S.

编辑

正如@WillNess 所指出的，我使用的语法不精确。实际上，双括号是\+ 被视为函子而不是运算符的结果。在符号后面加一个空格，我们可以改写

?- has(U,S),\+ (has(V,T),T>S).

Answer 2

试一试：

has(steve, 5).
has(mark, 6).
has(craig, 4).

?- findall(has(X, Y), has(X, Y), Z), maxhas(Z, has(Who, Max)), write([Who, Max]).

maxhas([has(X, Y)], has(X, Y)).
maxhas([has(_, Y)|Hs], has(A, B)) :- maxhas(Hs, has(A, B)), B >= Y.
maxhas([has(X, Y)|Hs], has(X, Y)) :- maxhas(Hs, has(_, B)), B < Y.

我明白了：

[mark, 6]Yes.

Answer 3

您可以使用标准谓词findall/3 和keysort/2：

| ?- findall(Value-Name, has(Name, Value), Pairs),
     keysort(Pairs, SortedPairs).

Pairs = [5-steve, 6-mark, 4-craig],
SortedPairs = [4-craig, 5-steve, 6-mark]
yes

您想要SortedPairs 列表中的最后一对。只需遍历列表，直到到达最后一个元素。我会把它留给你写一个last(List, Last) 谓词。

更新

Carlo 的解决方案非常地道 (+1)。但这也是 O(n^2)。我的解决方案（包括缺少的 last/2 谓词）是 O(2*n + n*log(n))。另一方面，由于创建了临时列表，它对垃圾收集器的影响略大。如果我们在 OP 中只有树事实，Carlo 的解决方案要快约 3 倍。对于大约 100 个事实，两种解决方案所花费的时间大致相同（请注意，确切的数字取决于所使用的 Prolog 系统）。对于大量的事实，复杂性上的差异越来越明显。