用 foldr 在二叉树中找到具有最小值的节点

Question

有人可以帮我定义一个函数 minTree，它使用 foldr 在二叉树中找到具有最小值的节点。 我开始了一些事情，但我不知道如何在我的代码中使用 foldr：

data Tree a 
    = Leaf
    | Node (Tree a) a (Tree a)
    deriving (Show, Eq)

  minTree :: (Ord a) => Tree a -> Maybe a
  minTree Leaf = Nothing
  minTree (Node Leaf a _) = Just a
  minTree (Node left a _) = minTree left
  minTree = foldr...

我被困在如何定义 foldr 以返回最小节点

Answer 1

一个可能的解决方案如下：

data Tree a 
    = Leaf
    | Node (Tree a) a (Tree a)
    deriving (Show, Eq)

instance Foldable Tree where
  foldr f ini Leaf = ini
  foldr f ini (Node left x right) = f x $ foldr f (foldr f ini right) left

minTree :: (Ord a) => Tree a -> Maybe a
minTree tree = foldr minMaybe Nothing tree

minMaybe :: (Ord a) => a -> Maybe a -> Maybe a
minMaybe x Nothing = Just x
minMaybe x (Just y) = Just (min x y)

Tree 的Foldable 实例实现是后序遍历（右-左-根），这是代码的主要部分。 minMaybe 可能可以避免使用内置函数，但我保持它的表现力，所以主要部分保持清晰。

正如@ammalloy 所指出的，我们可以摆脱minMaybe 并使用coerce、foldMap 和Min Semigroup。老实说，我不知道coerce 是如何工作的，但是foldMap 将一个函数应用于包装在具有Foldable 实例的数据类型中的数据，并使用他们的Monoidal 操作<> 聚合结果，这就是为什么此处使用Min。

data Tree a 
    = Leaf
    | Node (Tree a) a (Tree a)
    deriving (Show, Eq)

instance Foldable Tree where
  foldr f ini Leaf = ini
  foldr f ini (Node left x right) = f x $ foldr f (foldr f ini right) left

minTree :: (Ord a) => Tree a -> Maybe a
minTree = coerce . foldMap (Just . Min)