如何访问 CoffeeScript 类中的 arguments.callee？

Question

我有以下代码

class Foo 

  a: ->
    console.log arguments.callee.name

  b: ->
    @a()

  c: ->
    @a()


f = new Foo
f.b() #=> should output 'b'
f.c() #=> should output 'c'

问题：如何在我的类中获取调用函数的名称？

---

这是一个用例

class Something extends Stream

  foo: ->
    _helper 'foo', 'a', 'b', 'c'

  bar: ->
    _helper 'bar', 'my neighbor totoro'

  dim: ->
    _helper 'dim', 1, 2, 3

  sum: ->
    _helper 'sum', 'hello', 'world'

  _helper: (command, params...) ->
    @emit 'data', command, params...

something = new Something
something.foo()
something.bar()
# ...

我不想重复将每次调用的方法名称发送到我的私有 _helper 方法

Answer 1

所以要明确一点，我认为你拥有它的第二种方式是完全合理的，并且是要走的路。

但要回答您的问题，您可以动态生成每个函数以避免重新键入命令。

class Foo
  commands =
    foo: ['a', 'b', 'c']
    bar: ['my neighbor totoro']
    dim: [1,2,3]

  for own name, args of commands
    Foo::[name] = ->
      @emit 'data', name, args...

假设你希望函数有用，你仍然可以使用函数。

// ...
  commands =
    foo: (args...) -> return ['a', 'b', 'c']
    // ...

  for own name, cb of commands
    Foo::[name] = (command_args...) ->
      args = cb.apply @, command_args
      @emit 'data', name, args...

Answer 2

这就是我会做的：

class Something extends Stream
    constructor: ->
        @foo = helper.bind @, "foo", "a", "b", "c"
        @bar = helper.bind @, "bar", "my neighbor totoro"
        @dim = helper.bind @, "dim", 1, 2, 3
        @sum = helper.bind @, "sum", "hello", "world"

    helper = (command, params...) ->
        @emit 'data', command, params...

这种方法的优点是：

1. helper 函数是一个私有变量。无法通过实例直接访问。
2. helper 函数只声明一次，并在所有实例之间共享。
3. 函数foo、bar、dim和sum是partial applications的helper。因此它们不会为函数体消耗更多内存。
4. 它不需要像@loganfsmyth 的答案那样的循环。
5. 更干净了。

编辑：更简洁的方法是：

class Something extends Stream
    constructor: ->
        @foo = @emit.bind @, "data", "foo", "a", "b", "c"
        @bar = @emit.bind @, "data", "bar", "my neighbor totoro"
        @dim = @emit.bind @, "data", "dim", 1, 2, 3
        @sum = @emit.bind @, "data", "sum", "hello", "world"

当然，这有点多余，但您不能对 JavaScript 这样的语言有更多期望。这不是Factor。然而，它是可读的、干净的、易于理解的，而且最重要的是 - 正确。