如何访问 CoffeeScript 中的类方法？

Question

我在此做序言： 作为一个整体，我是 CoffeeScript 和 JavaScript 原型设计的新手。

话虽如此，我正在尝试在 CoffeeScript 中创建一个类的新对象，然后调用一个 getter 来检索变量，但结果却是我得到了一个“未定义”的响应。我做错了什么，或者我应该如何处理这个问题。我是新手，正在努力遵循 KISS 标准。

class TestHandler
  constructor: ->
  testArray = []
  getTestArray: ->
    @testArray

tH = new TestHandler()
tH.testArray.push 1 #testArray returns undefined
tH.getTestArray().push 1 #getTestArray returns undefined
console.log tH.getTestArray()

Answer 1

当你在 CoffeeScript 中创建一个类时，你在下面列出的每个方法都指向 prototype 属性（在本例中为 TestHandler.prototype），因此在该类的实例之间共享，但是每个其他属性都将是TestHandler 本身的成员（如果名称以 @ 开头）或作用域为 class 最终将编译为的函数的私有变量（就像您的 testArray = [] 一样）。这意味着，您的tH 不会有一个名为testArray 的属性。如果您希望它成为每个实例自己的属性，请将其放入构造函数中：

class TestHandler
    constructor: ->
        @testArray = []
    getTestArray: ->
        @testArray

tH = new TestHandler()
tH.testArray.push 1 #now everything works
tH.getTestArray().push 1
console.log tH.getTestArray()

---

一般来说，房产将降落在哪里取决于您在class 声明中的书写方式。看看这个CS代码

 class TestHandler
   constructor: ->
     @testArray = [] #1
   testArray = [] #2
   @testArray = [] #3
   getTestArray: -> #4
   testArray: [] #5

以及它编译成的代码：

 var TestHandler;

 TestHandler = (function() {
   var testArray;

   function TestHandler() {
     #1 @thisArray in constructor becomes instance property accessor
     this.testArray = [];
   }

   #2 becomes a local variable, not available outside this function
   testArray = [];

   #3 becomes a "static" property
   TestHandler.testArray = [];

   #4 is a method that goes to the prototype, so that it can be shared with all instances
   TestHandler.prototype.getTestArray = function() {};

   #5 is a property that goes to the prototype and can be shared with all instances (although this shouldn't be done unless you know what you do)
   TestHandler.prototype.testArray = [];

   return TestHandler;

 })();