如何部分比较两张地图？

Question

我想比较两个映射的部分相等性，即仅针对某些键。例如我有两张地图：

map1 = %{a: 1, b: 2, c: 3}
map2 = %{a: 1, c: 3, d: 4}

我只想比较两个键的映射：a 和 :c，所以上面的例子应该返回 true。

我正在寻找一个简短的通用解决方案，因为我的地图中有很多键。

Answer 1

如果事先知道一组键，一个通用且简单的解决方案是使用Enum.all?/2检查所有键的条件：

map1 = %{a: 1, b: 2, c: 3}   
map2 = %{a: 1, c: 3, d: 4}
keys = [:a, :c]

Enum.all?(keys, fn key -> map1[key] == map2[key] end) # true

编辑：如果您需要动态检测重叠键，您可以执行类似的操作

def partial_equal?(map1, map2) when is_map(map1) and is_map(map2) do
  Enum.all?(map1, fn {key, value} ->
    case map2 do
      %{^key => another_value} when another_value != value -> false
      _ -> true
    end
  end)
end

# or, more compact
Enum.all?(map1, fn {key, value} -> not match?(%{^key => v} when v != value, map2) end)

它将检查来自map1 的所有键值，并在找到map2 中具有不同值的键时立即使用false 保释。

partial_equal?(%{a: 1, b: 2, c: 3},  %{a: 1, c: 3, d: 4})  # true
partial_equal?(%{a: 1, b: 2, c: 3},  %{a: 1, c: 0})  # false

Answer 2

我会选择Map.take/2，这样会更惯用，并且能更好地阐明意图。

map1 = %{a: 1, b: 2, c: 3}
map2 = %{a: 1, c: 3, d: 4}

[map1, map2]
|> Enum.map(&Map.take(&1, [:a, :c]))
|> Enum.reduce(&Kernel.==/2)
#⇒ true

不过，对于大地图，@sabiwara 的解决方案效果更好，请参阅那里的 cmets。

Answer 3

我认为这个函数可以满足你的需要。

@doc """
Returns a boolean indicating if the given maps
have any key-value pairs in common.
"""
@spec have_any_key_value_pair_in_common?(map(), map()) :: boolean()
def have_any_key_value_pair_in_common?(map1, map2) do
  map_set1 = MapSet.new(map1)
  map_set2 = MapSet.new(map2)

  map_set1
  |> MapSet.intersection(map_set2)
  |> Enum.any?() 
end

我在这里所做的是将地图转换为“MapSets”，这就像数学集（每个元素都是唯一的）。当你这样做时，地图中的每个“元素”都是一个键值对，例如{:a, 1}.

然后我得到两个 MapSet 的“交集”。这将为我提供所有常见元素的列表，即两个映射共有的所有键值对。

有了这个列表，我只需要Enum.any? 得到一个布尔值（如果列表不为空则为真，如果为空则为假）。