数百个复选框从 True/False 变为 Yes/No

Question

我有一个不断更新的电子表格，用于跟踪患者的就诊情况。我有 2 列，我使用下面的 VBA 代码输入了多个复选框，这些复选框分配给它们所在的单元格。但是，我想添加一些东西，当我单击它们时，使复选框的值为是或否。电子表格中有超过 600 个，所以我需要一些可以同时涵盖所有这些的东西，而不必单独更改每一个。我会发布电子表格的图片，但我还不能，因为我是新用户并且没有声誉积分。有人可以帮忙吗？

Sub AddCheckBoxes()

Dim cb As CheckBox
Dim myRange As Range, cel As Range
Dim wks As Worksheet

Set wks = Sheets("Sheet1")

Set myRange = wks.Range("K2:K300, L2:L300")

For Each cel In myRange

Set cb = wks.CheckBoxes.Add(cel.Left, cel.Top, 30, 6)


With cb

    .Caption = ""
    .LinkedCell = cel.Address

End With

Next

End Sub

结束子

Answer 1

代码在创建复选框时，可以添加.OnAction ="MacroName"

 With cb
        .LinkedCell = cel.Address
        .Caption = ""
        .OnAction = "YesNoChkBox"    'will call the macro when the checkbox is clicked.
    End With

它的作用是在单击复选框时为其分配一个宏。然后宏会计算出被点击的复选框的范围，如果是真或现在，将显示“是”或“否”。

 Sub MakeCkBx()

    Dim cb As CheckBox
    Dim myRange As Range, cel As Range
    Dim wks As Worksheet

    Set wks = Sheets("Sheet1")

    Set myRange = wks.Range("K2:K21, L2:L21")

    For Each cel In myRange

        Set cb = wks.CheckBoxes.Add(cel.Left, cel.Top, 30, 6)

        With cb
            .LinkedCell = cel.Address
            .Caption = ""
            .OnAction = "YesNoChkBox"    'will call the macro when the checkbox is clicked.
        End With
        cel.HorizontalAlignment = xlRight
    Next

End Sub
Sub YesNoChkBox()
    Dim r As Range, x, CkBx As CheckBox
    Set CkBx = ActiveSheet.CheckBoxes(Application.Caller)
    Set r = Range(CkBx.LinkedCell)

    If CkBx = 1 Then
        r = "yes"
    Else
        r = "No"
    End If
End Sub

运行 MakeCkBx 宏，然后单击复选框以获取结果。

我有一个位于here 的application.caller 的简单示例