如何在 Linux x86 NASM 中打印字符？

Question

我正在尝试使用 NASM 打印单个字符或数字，目标是 x86 GNU/Linux 架构。

这是我正在使用的代码：

section .text
    global _start

_start:

    ; Linux printing preparation
    mov eax,4            
    mov ebx,1       

    ; Print 'A' character 
    mov ecx,'A'     ; ecx should contain the value to print
    mov edx,1       ; edx should contain how many characters to print
    int 80h

    ; System exit
    mov eax,1            
    mov ebx,0            
    int 80h

但是，运行此代码不会打印任何内容。我做错了什么？

Answer 1

ecx 应该包含一个指向 char 缓冲区开头的指针。所以你必须有你的缓冲区在内存中。您可以执行以下操作：

; Print 'A' character 
mov   eax, 4      ; __NR_write from asm/unistd_32.h (32-bit int 0x80 ABI)
mov   ebx, 1      ; stdout fileno

push  'A'
mov   ecx, esp    ; esp now points to your char
mov   edx, 1      ; edx should contain how many characters to print
int   80h         ; sys_write(1, "A", 1)

; return value in EAX = 1 (byte written), or error (-errno)

add   esp, 4      ; restore esp if necessary

您可以mov byte [esp], 'A' 或任何其他地址，如果可以覆盖堆栈上的任何内容。

或者您可以在section .rodata 中拥有一个字符数组，而不是即时存储。

---

使a write() system call 与const void *buf arg 是一个小数字（如'A'）将使它返回-EFAULT 而不会打印任何内容。无论如何，内核都必须检查指针，系统调用会返回错误，而不是在错误的指针上引发 SIGSEGV。

使用strace ./my_program 跟踪您实际进行的系统调用，包括解码返回值。

Answer 2

您正在执行的系统调用需要ecx 包含内存中的地址。这可以是任意文字地址（即在您的代码中，"A" 转换为地址 041h）、堆栈上的地址或由程序中的标签定义的地址。

这是在内存中定义一个字节并将其写入终端的标准输出流的示例：

    section .rodata  ; This section contains read-only data
buffer:    db 'A'    ; Define our single character in memory

    section .text
    global start
_start:
    ; Prints the letter 'A', then exits

    mov eax, 4      ; sys_write()
    mov ebx, 1      ; ... to STDOUT
    mov ecx, buffer ; ... using the following memory address
    mov edx, 1      ; ... and only print one character
    int 80h         ; SYSCALL

    mov eax, 1      ; Return to system
    mov ebx, 0      ; Exit zero, success
    int 80h         ; SYSCALL