在 nasm 中打印数字

Question

我已经编写了一个汇编代码来打印从 1 到 9 的数字，但是代码只打印 1，并且没有打印除 1 以外的其他元素，并且只接收到一个输出。这意味着循环也没有运行。我无法弄清楚我的代码有什么问题。

section .bss

        lena equ 1024
        outbuff resb lena

section .data

section .text

        global _start
        _start:
                nop
                mov cx,0

                incre:
                inc cx
                add cx,30h
                mov [outbuff],cx

                cmp cx,39h
                jg done

                cmp cx,39h
                jl print


                print:
                mov rax,1           ;sys_write
                mov rdi,1
                mov rsi,outbuff
                mov rdx,lena
                syscall
                jmp incre

                done:
                mov rax,60          ;sys_exit
                mov rdi,0
                syscall

我的操作系统是 64 位 Linux。此代码是使用 nasm 和以下命令构建的：nasm -f elf64 -g -o num.o num.asm 和 ld -o num num.asm

Answer 1

经过一些实验后重写了答案。

您的代码中有两个错误，还有一些效率低下。

首先，将 0x30 添加到数字（将其从数字 1 转换为 ASCII 1）。但是，您在循环内执行该增量。因此，您的第一次迭代 cx 是 0x31，第二次是 0x62（“b”），第三次是 0x93（无效的 UTf-8 序列）等等。

只需将 cx 初始化为 0x30 并从循环内删除添加。

但是还有另一个问题。 RCX 在系统调用期间被破坏。将cx 替换为r12 会导致程序运行。

除此之外，您将缓冲区的长度传递给write，但它只有一个字符。到目前为止的程序：

section .bss

        lena equ 1024
        outbuff resb lena

section .data

section .text

        global _start
        _start:
                nop
                mov r12,30h

                incre:
                inc r12
                mov [outbuff],r12

                cmp r12,39h
                jg done

                cmp r12,39h
                jl print


                print:
                mov rax,1           ;sys_write
                mov rdi,1
                mov rsi,outbuff
                mov rdx,1
                syscall
                jmp incre

                done:
                mov rax,60          ;sys_exit
                mov rdi,0
                syscall

除了现在，代码效率极低。您在相同条件下进行了两次比较，其中一个分支到下一条指令。

此外，如果您将中断条件移到代码末尾，您的代码会更快更小。此外，cx 是一个 16 位寄存器。 r12 是一个 64 位寄存器。我们实际上只需要 8 位。使用比需要更大的寄存器意味着我们所有的立即数都会浪费内存和缓存中的空间。因此，我们切换到r12 的 8 位变体。经过这些更改，我们得到：

section .bss

        lena equ 1024
        outbuff resb lena

section .data

section .text

        global _start
        _start:
                nop
                mov r12b,30h

                incre:
                inc r12b
                mov [outbuff],r12b

                mov rax,1           ;sys_write
                mov rdi,1
                mov rsi,outbuff
                mov rdx,1
                syscall

                cmp r12b,39h
                jl incre

                mov rax,60          ;sys_exit
                mov rdi,0
                syscall

您还可以做很多事情。例如，您调用write 系统调用 9 次，而不是填充缓冲区然后调用一次（尽管您已经分配了一个 1024 字节的缓冲区）。将 r12 初始化为零 (xor r12, r12) 然后添加 0x30 可能会更快。 （与 8 位版本的寄存器无关）。