在 Groovy 中从集合构建地图

Question

我们有以下相同类型的 Parent 和 Child 对象的遗留数据结构

Parent1(name1,code1,null)
  Child11(name11,code11,Parent1)
  Child12(name12,code12,Parent1)
Parent2(name2,code2,null)
  Child21(name21,code21,Parent2)
  Child22(name22,code22,Parent2)
etc.

我们有一个旧服务可用，它返回一个包含所有子对象的集合。不返回 Parent 对象，但我们可以为 Set 中的特定 Child 调用 getParent() getter 以获取其 Parent。我们需要从 Groovy 类中调用此服务，然后构建反映原始结构的 Map

def dataMap = [data:[["name":"name1", "code":"code1", 
                         "children":[["name":"name11", "code":"code11"], 
                                     ["name":"name12", "code":"code12"]]], 
                    ["name":"name2", "code":"code2", 
                         "children":[["name":"name21", "code":"code21"], 
                                     ["name":"name22", "code":"code22"]]]]] 

所以基本上 Map 键是父（名称，代码）对，值是各个子对象的（名称，代码）对的列表（地图实际上随后会呈现为 JSON）

作为 Groovy 的新手，我可能可以使用 Java 语法解决这个问题，但我想知道是否有使用 Groovy 特定功能的更简洁的解决方案？任何想法表示赞赏

Answer 1

据我了解，这是您的设置：

import groovy.transform.*
import groovy.json.*

@TupleConstructor(includeFields=true)
class Node {
    String name
    String code
    private Node parent

    String getParentName() { parent?.name }
    String getParentCode() { parent?.code }
}

def parent1 = new Node( 'name1',  'code1',  null )
def child11 = new Node( 'name11', 'code11', parent1 )
def child12 = new Node( 'name12', 'code12', parent1 )
def parent2 = new Node( 'name2',  'code2',  null )
def child21 = new Node( 'name21', 'code21', parent2 )
def child22 = new Node( 'name22', 'code22', parent2 )

// This is returned by a call to your API
Set nodes = [ child11, child12, child21, child22 ]

然后，您可以执行以下操作（可能还有其他路线，这仅适用于单深度树）

// Get a set of parent nodes
Set parents = nodes.collect { [ name:it.parentName, code:it.parentCode ] }

// Utility closure to return a name and code in a Map
def format = { Node n ->
    [ name: n.name, code: n.code ]
}

// Collect the formatted parents with their formatted children into a Map
def dataMap = [ data:parents.collect { p ->
    p + [ children:nodes.findAll { 
                       it.parentName == p.name && it.parentCode == p.code
                   }.collect { format( it ) } ]
} ]

// Print the JSON representation of this
println new JsonBuilder( dataMap ).toPrettyString()

应该打印出来：

{
    "data": [
        {
            "name": "name2",
            "code": "code2",
            "children": [
                {
                    "name": "name21",
                    "code": "code21"
                },
                {
                    "name": "name22",
                    "code": "code22"
                }
            ]
        },
        {
            "name": "name1",
            "code": "code1",
            "children": [
                {
                    "name": "name11",
                    "code": "code11"
                },
                {
                    "name": "name12",
                    "code": "code12"
                }
            ]
        }
    ]
}