如何在Delphi中模拟Ctrl+c

Question

有什么方法可以在 delphi 中模拟 Ctrl+C 命令吗？ 问题是我希望从另一个应用程序中，例如在选择目标文本后从记事本复制文本。

Answer 1

有什么方法可以模拟CTRL+C？

这样做的方法是使用Win32的SendInput函数来合成击键。这是一个例子：

procedure SendCtrlC;
var
  Inputs: array [0..3] of TInput;
begin
  ZeroMemory(@Inputs, SizeOf(Inputs));
  Inputs[0].Itype := INPUT_KEYBOARD;
  Inputs[0].ki.wVk := VK_CONTROL;
  Inputs[0].ki.dwFlags := 0; // key down
  Inputs[1].Itype := INPUT_KEYBOARD;
  Inputs[1].ki.wVk := ord('C');
  Inputs[1].ki.dwFlags := 0; // key down
  Inputs[2].Itype := INPUT_KEYBOARD;
  Inputs[2].ki.wVk := ord('C');
  Inputs[2].ki.dwFlags := KEYEVENTF_KEYUP;
  Inputs[3].Itype := INPUT_KEYBOARD;
  Inputs[3].ki.wVk := VK_CONTROL;
  Inputs[3].ki.dwFlags := KEYEVENTF_KEYUP;
  SendInput(4, Inputs[0], SizeOf(Inputs[0]));
end;

当然，您希望接收 CTRL+C 击键的应用程序需要具有输入焦点。

Answer 2

（让我先说使用剪贴板进行进程间通信是一个坏主意。剪贴板属于用户，您的应用程序只能在用户选择这样做的情况下使用它。）

如果您在记事本中选择了文本，这会将内容放入 Delphi 表单上的 TMemo（仅使用 TMemo 和 TButton；将 ClipBrd 添加到您的使用子句中）：

procedure TForm1.Button1Click(Sender: TObject);
var
  NpWnd, NpEdit: HWnd;
begin
  Memo1.Clear;
  NpWnd := FindWindow('Notepad', nil);
  if NpWnd <> 0 then
  begin
    NpEdit := FindWindowEx(NpWnd, 0, 'Edit', nil);
    if NpEdit <> 0 then
    begin
      SendMessage(NpEdit, WM_COPY, 0, 0);
      Memo1.Lines.Text := Clipboard.AsText;
    end;
  end;
end;

结果示例：

如果没有先选择文本，请先发送WM_SETSEL 消息。传递 0 和 '-1' 的值会选择所有文本。

procedure TForm1.Button1Click(Sender: TObject);
var
  NpWnd, NpEdit: HWnd;
begin
  Memo1.Clear;
  NpWnd := FindWindow('Notepad', nil);
  if NpWnd <> 0 then
  begin
    NpEdit := FindWindowEx(NpWnd, 0, 'Edit', nil);
    if NpEdit <> 0 then
    begin
      SendMessage(NpEdit, EM_SETSEL, 0, -1);
      SendMessage(NpEdit, WM_COPY, 0, 0);
      Memo1.Lines.Text := Clipboard.AsText;
    end;
  end;
end;