使用高阶函数查找列表的最大值

Question

我正在尝试使用过滤器（尽管我也可以使用 map 和/或 foldr）来查找列表的最大元素。

我尝试过滤掉每个小于 max 的数字，但它拒绝接受 max 作为过滤器参数。

这是我的代码：

 max' :: Ord a => [a] -> a
 max' xs = filter (< max) xs

这是我得到的错误：

* Couldn't match type `a' with `a0 -> a0 -> a0'
  `a' is a rigid type variable bound by
    the type signature for:
      max' :: forall a. Ord a => [a] -> a
    at Prog8.hs:50:1-25
  Expected type: [a0 -> a0 -> a0]
    Actual type: [a]
* In the second argument of `filter', namely `xs'
  In the expression: filter (< max) xs
  In an equation for max': max' xs = filter (< max) xs
* Relevant bindings include
    xs :: [a] (bound at Prog8.hs:51:6)
    max' :: [a] -> a (bound at Prog8.hs:51:1)

有没有办法在一个简单的过滤函数中写入 max'（或者可以将它与 map 或 foldr 结合使用）？

Answer 1

一个空列表没有最大元素，所以你不能用你提供的类型编写一个总函数。更明智的是

maximum' :: Ord a => [a] -> Maybe a

简单的方法是使用foldl'：

maximum' = foldl' gom Nothing where
  gom Nothing new = Just new
  gom (Just old) new
    | old < new = Just new
    | otherwise = Just old

但是你想要foldr。由于foldl' 实际上是根据foldr 定义的，所以这很容易！

foldl' f b0 xs = foldr gof id xs b0
  where
    gof x r b = b `seq` r (f b x)

内联，

maximum' xs = foldr gob id xs Nothing
  where
    --gob new r b = b `seq` r (gom b new)
    gob new r b = seq b $ r $
      case b of
        Nothing -> Just new
        Just old
          | old < new -> Just new
          | otherwise -> Just old

做一点手动严格性分析，这简化为

maximum' xs = foldr gob id xs Nothing
  where
    gob new r b = r $!
      case b of
        Nothing -> Just new
        Just old
          | old < new -> Just new
          | otherwise -> Just old

---

一个小警告：如果这是家庭作业并且你提交了我的解决方案，你的老师可能会怀疑。有一个更简单的方法，但效率也低得多，但我会让你搜索它。

Answer 2

首先，正如您所发现的，您想要的是：

max' :: Ord a => [a] -> [a]
max' xs = filter (< maximum xs) xs

如果您出于某种原因绝对专注于无点样式，并且只想使用高阶函数进行编写，这也可以：

max' :: Ord a => [a] -> [a]
max' = flip filter <*> ((>) <$> maximum)

但不要这样做，这太糟糕了。重复两次即可。