Excel VBA嵌套正则表达式替换

Question

是否可以在 Excel VBA 中嵌套正则表达式替换函数和/或作为单元格公式？

例如，我有以下文本：“Lorem [ipsum dolor sit] amet, [consetetur sadipscing] elitr。” （注意方括号）

是否有可能将其转换为：“Lorem ipsum_dolor_sit amet, consetetur_sadipscing elitr.”？

所以我想：

1. 找到方括号内的所有术语
2. 在其中：替换 所有带下划线的空格
3. 去掉方括号

并通过这些替换返回整个句子。

以我目前的尝试，我只能删除括号：

Function RegexReplace(...)
...
Set oRegex = CreateObject("VBScript.RegExp")
oRegex.Pattern = "\[([^\[\]]*)\]"
oRegex.Replace(strInput, "$1")
...

并将此函数作为公式嵌套在单元格中或代码oRegex.Replace(strInput, Replace("$1", " ", "_") 中似乎是不可能的，因为嵌套替换函数Replace(.. 在评估替换字符串$1 之前被调用，因此没有空白替换。

任何解决方案的建议？谢谢:-)

Answer 1

另一种解决方案是在每个循环中执行正则表达式，并且只获取第一个匹配项并为此更新结果。因此每个循环都会更新字符索引，您可以使用任何更改字符数的替换。 这里我也使用了子匹配，即没有括号（参见模式）。

Function RegexReplace(cell As Variant) As String
Dim oRegex As Object, m As Object
Dim strMatch As String

Set oRegex = CreateObject("VBScript.RegExp")
With oRegex
    .Pattern = "\[([^\[\]]*)\]"
    .Global = False
End With
RegexReplace = cell.Text
Do While oRegex.Test(RegexReplace)
    Set allMatches = oRegex.Execute(RegexReplace)
    Set FirstMatch = allMatches(0)
    strMatch = Replace(FirstMatch.SubMatches(0), " ", "_")
    RegexReplace = Left(RegexReplace, FirstMatch.FirstIndex) & strMatch & Mid(RegexReplace, FirstMatch.FirstIndex + Len(FirstMatch.Value) + 1)
    DoEvents
Loop

End Function

Answer 2

如果您修改代码，则可以将匹配项中的所有空格替换为下划线

Function RegexReplace(cell As Variant) As String
Dim oRegex As Object, m As Object, offset As Long
Set oRegex = CreateObject("VBScript.RegExp")
offset = 0
With oRegex
    .Pattern = "\[([^[\]]*)]"
    .Global = True
End With
RegexReplace = cell.Text
For Each m In oRegex.Execute(RegexReplace)
    RegexReplace = Left(RegexReplace, m.FirstIndex - offset) & Replace(m.SubMatches(0), " ", "_") & Mid(RegexReplace, m.FirstIndex + 1 + Len(m.Value) - offset)
    offset = offset + 2
Next m
End Function

\[([^[\]]*)] 模式将匹配 [，然后将除 [ 和 ] 之外的零个或多个字符捕获到第 1 组中，然后仅匹配 ]。然后，使用For Each m In oRegex.Execute(RegexReplace) 遍历所有匹配项，一旦找到匹配项，匹配前的子字符串、替换空格的匹配项（使用Replace(m.Submatches(0), " ", "_")）和匹配后的文本连接起来形成函数输出。