Jenkinsfile 代理“dockerfile”参数化“dir”参数

Question

我在 Jenkins 2.280 中使用具有顺序阶段的声明式管道。

dockerfile的dir参数应该从${params}获取：

pipeline {
  agent none
  parameters {
    choice(name: PLATFORM, choices: ['dir1', 'dir2', ...], description: '')
    string(name: FOO, defaultValue: 1001, description: 'Interesting number')
  }
  stages {
    stage('Top') {
      agent {
        dockerfile {
          filename 'Dockerfile'
          dir 'platforms/${params.PLATFORM}'   // <-- HERE
          label 'master'
          additionalBuildArgs '--build-arg FOO=${params.FOO}'
          args '--mount type=bind,source=/opt/tools,target=/tools,readonly'
        }
      }  // agent
      stages {
        stage('Checkout') {
          steps { checkout scm }
        }
        stage('Build') {
          sh """
            // call cmake
            // call ninja
          """
        }
        ...
      } // stages
    } // Top
  } // stages
} // pipeline

这似乎总是导致 Java NoSuchFileException：

java.nio.file.NoSuchFileException: /var/jenkins_home/workspace/<ws_name>/platforms/${params.PLATFORM}/Dockerfile
    at sun.nio.fs.UnixException.translateToIOException(UnixException.java:86)

如果我将dir 参数硬编码到一个有效的目录名称，那么我会遇到FOO 的问题：

[Pipeline] withEnv
[Pipeline] {
[Pipeline] isUnix
[Pipeline] readFile
[Pipeline] sh
14:18:02  /var/jenkins_home/workspace/<ws_name>@tmp/durable-5884cc09/script.sh: 1: /var/jenkins_home/workspace/<ws_name>@tmp/durable-5884cc09/script.sh: Bad substitution

这两件事怎么办？

有更好的方法吗？

更新：我的问题是管道项目名称中的“空格”。

Answer 1

我试图创建一个与您类似的示例。请看一下如何在声明式管道中使用 Docker 文件和 dockerfile 代理

Dockerfile

FROM alpine
ARG PACKAGE
RUN apk add ${PACKAGE}

Jenkinsfile

pipeline {
  agent {
     dockerfile {
        filename 'Dockerfile'
        dir "${params.DOCKERFILE_PATH}"
        additionalBuildArgs  "--build-arg PACKAGE=${params.PACKAGE}"
        args '-v /tmp:/tmp'
     }
   }
   parameters {
        string(name: 'DOCKERFILE_PATH', defaultValue: 'src01', description: 'Pick Dockerfile from a folder')
        text(name: 'PACKAGE', defaultValue: 'curl', description: 'Package To Be Installed')
   }
   stages {
     stage('build'){
        steps {
          sh 'git version'
        }
     } 
   }
}

groovy 必须插入你的运行时参数，为此，你必须用"" 包装它。 '' 不起作用

在你的情况下，它将是

dockerfile {
    filename 'Dockerfile'
    dir "platforms/${params.PLATFORM}"
    label 'master'
    additionalBuildArgs "--build-arg FOO=${params.FOO}"
    args '--mount type=bind,source=/opt/tools,target=/tools,readonly'
}