Bat文件列出文件，使用分号分隔符？

Question

到目前为止，我有这个：

@ECHO OFF

dir *.txt /c /b /on > content.txt

提供输出：

file1.txt
file2.txt
file3.txt

但我需要这样，每行用分号隔开：

file1.txt;
file2.txt;
file3.txt;

我假设我可能需要编写 for 循环并添加字符串“;”某处，但我不知道在哪里或如何做到这一点。或者有没有办法只设置一个特定的分隔符？

编辑：

我的用例发生了变化，我认为如果在子文件夹中也列出文件会更好，但是“/”应该替换为空格“”。

示例输出：

file1.txt;
file2.txt;
subfolder1 file1.txt;
subfolder2 file1.txt;

请注意，我不想要完整的父路径，只想要子文件夹。

Answer 1

快速单行batch-file回答：

@(For /F Tokens^=*^ Delims^=^ EOL^= %%G In ('Dir "*.txt" /A:-D /B /O:N 2^>NUL') Do @Echo %%G;) 1>"content.log"

…在cmd:

(For /F Tokens^=*^ Delims^=^ EOL^= %G In ('Dir "*.txt" /A:-D /B /O:N 2^>NUL') Do @Echo %G;) 1>"content.log"

我决定输出到一个.log 文件，这样列表就不会包含它自己。

请使用内置帮助了解每个命令的工作原理。

当您阅读帮助信息时，请注意“简单”for 循环不会拾取所有文件，例如它会忽略所有隐藏文件。此外，尽管您可能从测试中获得任何第一印象，但返回文件的顺序取决于文件系统和类型。 dir 命令是确保排序顺序的最有效方式。

---

[编辑/]

这是一个batch-file 解决方案，（因为这是您发布的答案），用于您的全新且完全不同的问题。

@(For /F Tokens^=*^ Delims^=^ EOL^= %%G In ('Dir "*.txt" /A:-D /B /O:N /S 2^>NUL') Do @(Set "FileName=%%~dpG" & SetLocal EnableDelayedExpansion & Set "Filename=!FileName:~,-1!" & For %%H In ("!FileName:%__CD__%=!") Do @EndLocal & Echo %%~H %%~nxG;)) 1>"content.log"

将来，当您对所提出的问题已有答案时，不要更改该问题，因为不仅主要命令不同，而且预期的结果格式也不同。

Answer 2

一个简单的for 循环就可以了：

@(for %%i in (*.txt) do @echo %%i;)>"content.txt"

但是，如果 contents.txt 存在，它也会将其内容回显给自身，因此您可以将其排除。

@(for %%i in (*.txt) do @if /i not "%%~i" == "content.txt" @echo %%i;)>"content.txt"

如果计划还要遍历子目录，请运行 for /R

Answer 3

我找到了列出子文件夹的部分解决方案，不包括父路径。它并不完美（如上面 cmets 所述，for 循环并不准确，我对 pushd 命令也不满意），但可以。我用“空格”代替了\，因为我需要它。

@echo off
setlocal enabledelayedexpansion
pushd "c:\users\documents\"
(
  for /r %%a in (*.txt) do (
    set x=%%a
    set x=!x:%cd%=!;
    echo !x:\= !
  )
)>filelist.log
popd

代码说明：

首先我删除带有set x=!x:%cd%=!; 的父路径（感叹号替换%，请参阅enabledelayedexpansion 帮助），然后在回显时删除斜杠。