使用 Bat 文件分割以分号为分隔符的字符串

Question

我想使用批处理删除一个特殊路径。

我不能使用set somevar=" %path:specialstr=%"，因为specialstr 有动态部分。我可以使用批处理从%path%这样的大字符串中删除%cd%产生的字符串吗？

Answer 1

关注Dennis van Gils' advice，使用Delayed Expansion如下：

SETLOCAL EnableExtensions EnableDelayedExpansion
set "specialstr=%CD%\"
set "somevar=!path:;%specialstr%;=;!"

如果由于某种原因不能使用延迟扩展，请使用call set（阅读Advanced usage : CALLing internal commands）：

• 警告：%path% 变量中的某些部分路径包含 facultative 尾随反斜杠，而其他不包含。
• call set "somevar=%%path:;%specialstr%;=;%%" 最常见的用法。
• call set "somevar=%%path:;%specialstr%=%%" 如果;%specialstr% 是%path% 的尾随部分，但注意 Variable Edit/Replace 贪婪 并替换所有出现 ;%specialstr% in %path%。
• 如果%specialstr%; 是%path% 的前导部分，则使用call set "somevar=%%path:%specialstr%;=%%"，但小心同样小心。

一个示例脚本：

@ECHO OFF
SETLOCAL EnableExtensions DisableDelayedExpansion
where p.bat
pushd "C:\Utils"
set "specialstr=%CD%\"
popd
echo  specialstr=%specialstr%
echo    path end=...%path:~-46%
call set "somevar=%%path:;%specialstr%=%%"       
echo somevar end=...%somevar:~-36%
SETLOCAL
    set "path=%somevar%" 
    echo    path end=...%path:~-36%
    where p.bat
ENDLOCAL
where p.bat

输出（仅显示%path% 和%somevar% 变量的一些尾随字符以提高可读性）：

==> D:\bat\SO\38017804.bat
C:\Utils\p.bat
 specialstr=C:\Utils\
   path end=...Microsoft SQL Server\120\Tools\Binn\;C:\Utils\
somevar end=...Microsoft SQL Server\120\Tools\Binn\
   path end=...Microsoft SQL Server\120\Tools\Binn\
INFO: Could not find files for the given pattern(s).
C:\Utils\p.bat