在 Fortran 中将派生类型的指针分配给相同类型的目标

Question

我想在派生类型中分配一个指针，该派生类型包含在同一派生类型中。下面的代码给了我下面的错误。这是怎么回事，我该如何解决？

   24 |         zoos(i)%tigers(1) => zoos(i)%animals(1, 1)
      |        1
Error: Expected bounds specification for 'zoos' at (1)

module mo_zoo
    implicit none
    type zoo
        integer, dimension(:,:), pointer :: animals
        integer, dimension(:), pointer :: tigers
        integer, dimension(:), pointer :: ducks
    end type zoo
   
    save
        type(zoo), dimension(:), pointer :: zoos
end module mo_zoo

program test
    use mo_zoo
    implicit none
    integer :: n_zoos
    integer :: i

    n_zoos = 4
    allocate(zoos(n_zoos))

    do i = 1, n_zoos
        allocate(zoos(i)%animals(10, 2))
        zoos(i)%tigers(1) => zoos(i)%animals(1, 1)
        zoos(i)%ducks(1) => zoos(i)%animals(1, 2)
    end do
end program test

Answer 1

问题与派生类型无关，报错信息错误。

问题是zoos(i)%ducks是一个指向数组的指针，而不是一个指针数组，所以你需要将zoos(i)%ducks指向zoos(i)%animals(:, 2)，而不是zoos(i)%ducks(1)指向zoos(i)%animals(1, 2)。

这个in this answer之前已经谈过了。

我相信这可以满足您的需求：

module mo_zoo
    implicit none
    type zoo
        integer, dimension(:,:), pointer :: animals
        integer, dimension(:), pointer :: tigers
        integer, dimension(:), pointer :: ducks
    end type zoo
   
    save
        type(zoo), dimension(:), pointer :: zoos
end module mo_zoo

program test
    use mo_zoo
    implicit none
    integer :: n_zoos
    integer :: i

    n_zoos = 4
    allocate(zoos(n_zoos))

    do i = 1, n_zoos
        allocate(zoos(i)%animals(10, 2))
        zoos(i)%tigers => zoos(i)%animals(:, 1)
        zoos(i)%ducks => zoos(i)%animals(:, 2)
    end do
end program test

我还想提供一个框架挑战。正如 cmets 所指出的，尤其是 Ian Bush 所指出的，Fortran 中的指针是出了名的容易出错。

我建议用allocatables 替换任何分配的pointers。如果pointers 指向它们，这些allocatables 也必须是targets，如下所示：

module mo_zoo
    implicit none
    type zoo
        integer, dimension(:,:), allocatable :: animals
        integer, dimension(:), pointer :: tigers
        integer, dimension(:), pointer :: ducks
    end type zoo
   
    save
        type(zoo), dimension(:), allocatable, target :: zoos
end module mo_zoo

program test
    use mo_zoo
    implicit none
    integer :: n_zoos
    integer :: i

    n_zoos = 4
    allocate(zoos(n_zoos))

    do i = 1, n_zoos
        allocate(zoos(i)%animals(10, 2))
        zoos(i)%tigers => zoos(i)%animals(:, 1)
        zoos(i)%ducks => zoos(i)%animals(:, 2)
    end do
end program test

在可能的情况下，使用allocatables 比使用pointers 有很多优势：

• allocatables 占用的内存将在allocatables 退出范围时自动释放¹。
• 编译器可以对allocatables 做出比pointers 更强的假设，有时会导致代码更快。

---

¹ 至少，根据 Fortran 标准，这是正确的。一些编译器（尤其是this bug）存在几个与最终确定相关的突出问题。