为什么 try... except end; 没有捕获到异常？

Question

我有这段代码（在 iOS 和 Delphi Tokyo 下运行）：

procedure TMainForm.Button1Click(Sender: TObject);
var aData: NSData;
begin    
  try    
      try
        aData := nil;
      finally
        // this line triggers an exception
        aData.release;
      end;    
  except
    on E: Exception do begin
      exit;
    end;
  end;

end;

通常应该在except end 块中捕获异常，但在这种情况下，它不会被处理程序捕获，而是传播到Application.OnException 处理程序。

地址0000000100EE9A8C的访问冲突，访问地址 0000000000000000

我错过了什么吗？

Answer 1

这是 iOS 和 Android 平台上的一个错误（实际上是一个功能）（可能在其他具有 LLVM 后端的平台上——尽管没有明确记录）。 p>

核心问题是nil引用上的虚方法调用导致的异常构成硬件异常，该异常未被最近的异常处理程序捕获，并传播到下一个异常处理程序（在本例中为应用程序异常处理程序）。

Use a Function Call in a try-except Block to Prevent Uncaught Hardware Exceptions

使用 iOS 设备的编译器，除了块可以捕获硬件 仅当 try 块包含方法或函数调用时才会出现异常。 这是与编译器的 LLVM 后端相关的差异， 如果在 try 块中没有调用任何方法/函数，则无法返回。

在 iOS 和 Android 平台上显示该问题的最简单代码是：

var
  aData: IInterface;
begin
  try
    aData._Release;
  except
  end;
end;

在 Windows 平台上执行上述代码按预期工作，异常被异常处理程序捕获。上面的代码中没有nil 赋值，因为aData 是接口引用，它们在所有平台上都会被编译器自动取消。添加nil 分配是多余的，不会改变结果。

---

为了表明异常是由虚方法调用引起的

type
  IFoo = interface
    procedure Foo;
  end;

  TFoo = class(TInterfacedObject, IFoo)
  public
    procedure Foo; virtual;
  end;

procedure TFoo.Foo;
var
  x, y: integer;
begin
  y := 0;
  // division by zero causes exception here
  x := 5 div y;
end;

在以下所有代码变体中，异常会转义异常处理程序。

var
  aData: IFoo;
begin
  try
    aData.Foo;
  except
  end;
end;

var
  aData: TFoo;
begin
  try
    aData.Foo;
  except
  end;
end;

即使我们改变Foo的方法实现并从中删除所有代码，仍然会导致转义异常。

---

如果我们将 Foo 声明从 virtual 更改为 static，除零引起的异常将被正确捕获，因为在 nil 引用上调用静态方法是允许的，并且调用本身不会抛出任何异常 - 因此构成函数调用文档中提到。

type
  TFoo = class(TInterfacedObject, IFoo)
  public
    procedure Foo; 
  end;

  TFoo = class(TObject)
  public
    procedure Foo; 
  end;

另一个导致异常的静态方法变体也可以正确处理，是将x 声明为TFoo 类字段并在Foo 方法中访问该字段。

  TFoo = class(TObject)
  public
    x: Integer;
    procedure Foo; 
  end;

procedure TFoo.Foo;
var
  x: integer;
begin
  x := 5;
end;

---

回到涉及NSData 参考的原始问题。 NSData 是 Objective-C 类，在 Delphi 中表示为接口。

  // root interface declaration for all Objective-C classes and protocols
  IObjectiveC = interface(IInterface)
    [IID_IObjectiveC_Name]
  end;

由于在接口引用上调用方法始终是通过 VMT 表的虚拟调用，因此在这种情况下，其行为方式与直接在对象引用上调用的虚拟方法调用类似（表现出相同的问题）。调用本身会引发异常，并且不会被最近的异常处理程序捕获。

---

解决方法：

引用可能是nil 的代码中的一种解决方法是在对其调用虚拟方法之前检查nil。如果需要，在 nil 引用的情况下，我们还可以引发常规异常，这些异常将被封闭的异常处理程序正确捕获。

var
  aData: NSData;
begin
  try
    if Assigned(aData) then
      aData.release
    else
      raise Exception.Create('NSData is nil');
  except
  end;
end;

文档中提到的另一种解决方法是将代码放在附加函数（方法）中

procedure SafeCall(const aData: NSData);
begin
  aData.release;
end;

var
  aData: NSData;
begin
  try
    SafeCall(aData);
  except
  end;
end;