VBA MsgBox 导致错误

Question

在我的 VBA 项目中，我偶尔会弹出 MsgBox 以通知用户在子例程运行后某些内容已“完成”或“更新”。 如果没有 MsgBox，它似乎运行良好，但插入一个似乎给我一个错误。 不确定是否有必要在此处显示整个代码，因为它非常大，但在子例程结束时我只想...

MsgBox ("Completed")

后面是End Sub

但是，当我运行它然后单击 Msgbox 上的 OK 时，我收到一个运行时错误，单击 DeBug 时，它会突出显示 End Sub。

有什么理由会引发这样的错误吗？ 我错过了什么吗？ 非常感谢

这里有一些代码

'Add unique data to new location
For i = 1 To UnqArray1.Count
 rCell(i, 1) = UnqArray1(i)
Next

'Move Split Array into a new array
Set rTable2 = rCell
rng2() = rTable2.Value

'Filter into unique items
On Error Resume Next
For Each b In rng2
UnqArray2.Add b, b
Next

'Clear location
rCell.Clear

'Add new array to location
For i = 1 To UnqArray2.Count
rCell(i, 1) = UnqArray2(i)
Next

'Find the end of the category list
lastrow = Worksheets("CatMatch").Range("Q100000").End(xlUp).Row

'Sort alphabetically
Worksheets("CatMatch").Range("Q1:Q" & lastrow).Sort key1:=Range("Q1"), order1:=xlAscending, Header:=xlNo

'Copy it to CatMatch
Worksheets("CatMatch").Range("Q1:Q" & lastrow).Copy Destination:=Worksheets("CatMatch").Range("B15")

MsgBox "Completed"

End Sub

Answer 1

我无法重现您的错误，但您几乎可以肯定没有MsgBox 运行正常是不正确的。问题是您的代码问题被片段中的On Error Resume Next 隐藏了：

'Filter into unique items
On Error Resume Next
For Each b In rng2
UnqArray2.Add b, b
Next

两个cmets：

1) 如果您正在尝试使用RemoveDuplicates 方法，那为什么不使用呢？

2) 您的代码使用的事实是，如果您尝试添加重复键，集合会引发错误。这是对On Error Resume Next 的有效使用——但只有在您完成向集合添加键时将其关闭。比如：

On Error Resume Next
    For Each b In rng2
        UnqArray2.Add b, b
    Next
On Error GoTo 0

养成的一个好习惯是将On Error Resume Next 和On Error GoTo 0 视为定义一个代码块，甚至可能像我上面所做的那样缩进代码块内的代码。一个更好的习惯是不要假设只会发生一种错误。上面的代码预计可能会出现错误457（这是与尝试添加重复键相对应的错误号 - 您需要搜索文档才能找到它，或者只是在没有错误处理的情况下运行代码并查看它是如何崩溃）。任何其他都表明存在其他问题。为了最大限度地保证安全，您可以执行以下操作：

On Error Resume Next
    For Each b In rng2
        UnqArray2.Add b, b
        If Err.Number > 0 And Err.Number <> 457 Then
            MsgBox "Unhandled error: " & Err.Number
            Exit Sub
        End If
    Next
On Error GoTo 0

这样做不会解决您的问题，但应该让您的实际问题更加明显。