Workbook_BeforeClose MsgBox 错误

Question

我正在尝试创建一个控件，该控件要求用户在关闭工作簿之前在特定单元格中输入信息。如果用户尝试关闭时单元格为空，则应提示他们留在工作簿中并输入信息或退出而不保存。如果单元格已填充，则工作簿应自动保存。

下面是我目前设法想出的，放在 ThisWorkbook 对象中。我遇到的问题是，在出现 MsgBox 并选择了一个选项后，它会再次出现。我无法弄清楚为什么会发生这种情况，所以希望这里有人能指出我错过了什么。

注意，我只想关闭当前活动的工作簿，而不是退出整个应用程序。因此，如果用户打开了其他 Excel 窗口，我也不希望这些窗口也被关闭。

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    If Range(“A1”).Value = “” Then
        OutPut = Msgbox (“A1 is empty. Exit without saving?”, vbOKCancel + vbDefaultButton2)
        If OutPut = 1 Then
            ThisWorkbook.Close False
        Else: Cancel = True
            Exit Sub
        End If
    End If
ActiveWorkbook.Save
End Sub

Answer 1

好吧，你做尝试再次使用ThisWorkbook.Close False关闭工作簿，这就是第二个事件的来源。

改为使用ThisWorkbook.Saved = True 来防止弹出确认对话框：

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Dim OutPut As VbMsgBoxResult

    If Range("A1").Value = "" Then
        OutPut = MsgBox("A1 is empty. Exit without saving?", vbOKCancel + vbDefaultButton2)
        If OutPut = vbOK Then
            ThisWorkbook.Saved = True
        Else
            Cancel = True
        End If
    Else
        ThisWorkbook.Save
    End If
End Sub