文件处理 perl - split 产生非常小的数组

Question

美好的一天。我有一个要处理的大文本文件，按如下方式组织：

A
B 87368911
C 165368993    165369000       165369007       165369014       165369021       165369028
D 3299941
E 3221521
F 5909327
G 14740025      14740019        14740031        14740037
H 4446477      4640745

我想将它拆分为数组的哈希，以第一列作为键，如果有的话，将值放在一个可迭代的数组中（在 A 的情况下，没有，如您所见） .为此，我制作了以下代码（略有截断，我显然打开了文件并有周围的代码）：

my %resolvedreads;

while (my $line = <IN>) {
    my @thisline = $line =~ m/(\S+)/g;
    $resolvedreads{$thisline[0]} = @thisline[1 .. $#thisline];
    print join "\t", @{$resolvedreads{$thisline[0]}}, "\n";
}

我什至没有真正测试这个，因为它看起来很微不足道。显然我应该有，因为它给了我这个：

Use of uninitialized value $thisline[0] in hash element at resolved_reads_purifier.pl line X-1, <IN> line 1.
Use of uninitialized value $thisline[0] in hash element at resolved_reads_purifier.pl line X, <IN> line 1.
Can't use an undefined value as an ARRAY reference at resolved_reads_purifier.pl line X, <IN> line 1.

我发现自己对此感到有些困惑。进一步调查发现，该行确实是分裂的，但每个数组的长度都是 1 或 2。

那是什么？我觉得我在这里错过了一些基本的东西，我已经无能为力了。尽管在我看来几乎完全相同，但我之前的代码实际上已编译。

Answer 1

问题是当文件记录只有一个字段时，$#thisline 为零，所以@thisline[1 .. $#thisline] 是@thisline[1 .. 0]，这是一个空列表。将其分配给给定您undef

的标量

除此之外还有一个问题

$resolvedreads{$thisline[0]} = @thisline[1 .. $#thisline]

因为您将列表分配给标量，并且您通常只会获得列表的最后一个元素$thisline[-1]。此时您应该真正分配一个 数组引用

这就是我将如何编码您的问题

use strict;
use warnings;

my %resolvedreads;

while ( <DATA>) {
    my ($key, @values) = split;
    next unless defined $key;        # Skip blank records
    $resolvedreads{$key} = \@values;
}

use Data::Dump;
dd %resolvedreads;

__DATA__
A
B 87368911
C 165368993    165369000       165369007       165369014       165369021       165369028
D 3299941
E 3221521
F 5909327
G 14740025      14740019        14740031        14740037
H 4446477      4640745

输出

{
  A => [],
  B => [87368911],
  C => [165368993, 165369000, 165369007, 165369014, 165369021, 165369028],
  D => [3299941],
  E => [3221521],
  F => [5909327],
  G => [14740025, 14740019, 14740031, 14740037],
  H => [4446477, 4640745],
}

Answer 2

所以我看到了几件事。上面提到的分配数组时的标量与列表上下文。另一件事是您的切片 [1...#@array] 以“1”开头，但 A 行不存在索引 1，因此您的错误消息。这是工作代码：

use Modern::Perl '2013';
use Data::Dumper;

my $text = 'A
B 87368911
C 165368993    165369000       165369007       165369014       165369021       165369028
D 3299941
E 3221521
F 5909327
G 14740025      14740019        14740031        14740037
H 4446477      4640745';

my $fh;
open($fh, '<', \$text);

my %resolvedreads;

while (my $line = <$fh>) {
  chomp $line;
  my @thisline = $line =~ m/(\S+)/g;
  my $index    = shift @thisline;
  $resolvedreads{$index} = \@thisline;

}

say Dumper(\%resolvedreads);

Answer 3

$resolvedreads{$thisline[0]} = @thisline[1 .. $#thisline];

在标量上下文中将一个数组赋给一个哈希值，实际上和

$resolvedreads{$thisline[0]} = scalar @thisline[1 .. $#thisline];

或

$resolvedreads{$thisline[0]} = $#thisline;

$resolvedreads{$thisline[0]} = $thisline[$#thisline];

从您帖子的其余部分看来，您想为哈希值分配一个数组引用

$resolvedreads{$thisline[0]} = [ @thisline[1 .. $#thisline] ];

同样，您可以将列表分配给列表上下文中的列表

@{$resolvedreads{$thisline[0]}} = @thisline[1 .. $#thisline];