不再在 VIM 中弄乱空格

Question

我有一个BufWritePre 钩子添加到我的.vimrc 中，它在保存缓冲区之前修剪尾随空格。在编辑我自己的代码或其他也有始终删除尾随空格的策略的其他人的代码时，这对我来说非常方便。但是，这让我有时会弄乱其他人的空白，这在版本控制中看起来不太好。

我有两个想法，一般来说如何解决这个问题，我都有具体的问题：

选项 1

打开文件后（可能使用BufReadPost钩子），检测文件中是否有尾随空格。如果是，则设置一个缓冲区本地标志来发出信号。如果设置了标志，请在保存前禁用修剪。

这种方法的问题是我似乎不知道如何检测缓冲区中是否有尾随空格。我知道=~，但是如何将缓冲区内容作为字符串获取？或者更好的是，我可以使用/\s+$<cr> 进行搜索，但是如何检查搜索是否成功（如果有命中）？

选项 2（更智能）

如果空白修剪只发生在实际修改的行上会更好。这样我就可以不必关心代码中的尾随空格，但仍然不会弄乱文件的其余部分。这就提出了一个问题：我能否以某种方式获得我添加或修改的行的行号？

我是 Vimscript 的新手，如果有任何提示或提示，我将不胜感激 :)

更新：我现在选择了选项 1：

" configure list facility
highlight SpecialKey term=standout ctermbg=yellow guibg=yellow
set listchars=tab:>-,trail:~

" determine whether the current file has trailing whitespace
function! SetWhitespaceMode()
  let b:has_trailing_whitespace=!!search('\v\s+$', 'cwn')
  if b:has_trailing_whitespace
    " if yes, we want to enable list for this file
    set list
  else
    set nolist
  endif
endfunction

" trim trailing whitespace in the current file
function! RTrim()
  %s/\v\s+$//e
  noh
endfunction

" trim trailing whitespace in the given range
function! RTrimRange() range
  exec a:firstline.",".a:lastline."substitute /\\v\\s+$//e"
endfunction

" after opening and saving files, check the whitespace mode
autocmd BufReadPost  * call SetWhitespaceMode()
autocmd BufWritePost * call SetWhitespaceMode()
" on save, remove trailing whitespace if there was already trailing whitespace
" in the file before
autocmd BufWritePre  * if !b:has_trailing_whitespace | call RTrim() | endif

" strip whitespace manually
nmap <silent> <leader>W :call RTrim()<cr>
vmap <silent> <leader>W :call RTrimRange()<cr>

Answer 1

选项 1 可以从 search() 函数中受益，如下所示：

let b:has_trailing_spaces=!!search('\v\s+$', 'cwn')

search() 函数返回匹配的行数（它们从 1 开始），如果没有找到则返回 0，!! 将其变为 1 或 0，删除关于在哪一行 search() 找到尾随空格的信息。没有n 标志search() 移动光标，我猜这是不希望的。如果没有w，它可能只搜索光标之后的缓冲区部分（实际上取决于'wrapscan' 选项）。

提议的选项 2 实现是使用 InsertLeave 和 '[、'] 标记的 hack：

augroup CleanInsertedTrailingSpaces
    autocmd!
    autocmd InsertLeave * let wv=winsaveview() | keepjumps lockmarks '[,']s/\s\+$//e | call winrestview(wv)
augroup END

它假定您只在键入后添加尾随空格。如果您在插入模式下将光标移过行，它将中断。您也可以尝试添加

    autocmd CursorHold * if getpos("'.")[1]!=0 | let wv=winsaveview() | keepjumps lockmarks '.s/\s\+$//e | call winrestview(wv) | endif

，这应该删除最后更改行的尾随空格（只有一行，'[ 和 '] 不能在这里使用，因为它们指向第一行和最后一行通常很有用）。两个自动命令都应该向撤消树添加信息。

选项 2 有第二个选项：git annotate 能够注释文件的当前状态，因此您可以使用 grep 过滤掉包含尾随空格和未提交更改的行，并使用挂钩清除在提交之前从他们那里得到不需要的空格。很遗憾，但hg annotate 无法做到这一点，因此您将不得不编写更复杂的东西，可能在 python 中。关于其他 VC 系统，我无话可说。

我想如果您使用set list listchars+=trail:- 来查看此类空格并因此能够在它们意外出现时手动删除它们会更好（我个人不记得自己经常意外添加尾随空格，尽管在 cmets 和我故意使用它们来表明该段继续）。你是怎么做才会出现这个问题的？

Answer 2

我倾向于不让 vim 自动修剪任何东西。正如您所说，如果处理其他人的代码，这可能是一场噩梦，并且可能导致不必要的冲突。为了保持我自己的代码整洁，我采取的方法是让空白可见。使用 vim 可以通过将以下内容添加到您的 ~/.vimrc 文件中来实现：

highlight SpecialKey ctermfg=DarkGray
set listchars=tab:>-,trail:~
set list

结果是这样显示空白：

这允许我在编写文件时保持文件清洁。大多数其他 (GUI) 编辑器也能够显示空白。

Answer 3

" Show trailing whitepace and spaces before a tab:
:highlight ExtraWhitespace ctermbg=red guibg=red
:match ExtraWhitespace /\s\+$\| \+\ze\t/
:autocmd ColorScheme * highlight ExtraWhitespace ctermbg=red guibg=red

这样，任何不好的空白都会以红色发光。很难错过。