maximumBy 的惯用单子版本会是什么样子？

Question

如何获得有效容器的最大元素，其中要比较的计算属性也会触发效果？

必须有更易读的方式来做这样的事情：

latest dir = Turtle.fold (z (ls dir)) Fold.maximum

z :: MonadIO m => m Turtle.FilePath -> m (UTCTime, Turtle.FilePath)
z mx = do
    x <- mx
    d <- datefile x
    return (d, x)

我使用重载版本而不是非重载版本maximumBy，但后者似乎更适合临时属性选择。

我怎样才能更有条理地解决类似的问题？

Answer 1

所以我对 Turtle 一无所知；不知道这是否适合 Turtle 生态系统的其他部分。但是，既然您在 cmets 中说服了我 maximumByM 值得手写，那么我将这样做：

maximumOnM :: (Monad m, Ord b) => (a -> m b) -> [a] -> m a
maximumOnM cmp [x] = return x -- skip the effects if there's no need for comparison
maximumOnM cmp (x:xs) = cmp x >>= \b -> go x b xs where
    go x b [] = return x
    go x b (x':xs) = do
        b' <- cmp x'
        if b < b' then go x' b' xs else go x b xs

我通常更喜欢 *On 版本的事物——它采用一个映射到 Orderable 元素的函数——而不是 *By 版本——它采用一个直接进行比较的函数。 maximumByM 会很相似，但有类似 Monad m => (a -> a -> m Ordering) -> [a] -> m a 的类型，但这可能会迫使您为每个 a 重做效果，我猜这不是您想要的。我发现 *On 更常与我想做的事情和我想要的性能特征相匹配。

Answer 2

由于您已经熟悉Fold，您可能想了解FoldM，它与此类似。

data FoldM m a b =
  -- FoldM step initial extract
  forall x . FoldM (x -> a -> m x) (m x) (x -> m b)

你可以写：

maximumOnM ::
  (Ord b, Monad m)
  => (a -> m b) -> FoldM m a (Maybe a)
maximumOnM f = FoldM combine (pure Nothing) (fmap snd)
  where
    combine Nothing a = do
      f_a <- f a
      pure (Just (f_a, a))
    combine o@(Just (f_old, old)) new = do
      f_new <- f new
      if f_new > f_old
        then pure $ Just (f_new, new)
        else pure o

现在您可以使用Foldl.foldM 在列表（或其他Foldable 容器）上运行折叠。与 Fold 一样，FoldM 也有一个 Applicative 实例，因此您可以将多个有效折叠组合成一个，将每个折叠的效果交错并组合它们的结果。

Answer 3

可以使用 reducers 包在可折叠设备上运行效果。

我不确定它是否正确，但它利用了现有的组合器和实例（Bounded (Maybe a) 除外）。

import Data.Semigroup.Applicative (Ap(..))
import Data.Semigroup.Reducer (foldReduce)
import Data.Semigroup (Max(..))
import System.IO (withFile, hFileSize, IOMode(..))

-- | maxLength
--
-- >>> getMax $ maxLength ["abc","a","hello",""]
-- 5
maxLength :: [String] -> (Max Int)
maxLength = foldReduce . map (length)

-- | maxLengthIO
--
-- Note, this runs IO...
--
-- >>> (getAp $ maxLengthIO ["package.yaml", "src/Lib.hs"]) >>= return . getMax
-- Just 1212
--
-- >>> (getAp $ maxLengthIO []) >>= return . getMax
-- Nothing
maxLengthIO :: [String] -> Ap IO (Max (Maybe Integer))
maxLengthIO xs = foldReduce (map (fmap Just . f) xs) where
    f :: String -> IO Integer
    f s = withFile s ReadMode hFileSize

instance Ord a => Bounded (Maybe a) where
    maxBound = Nothing
    minBound = Nothing