`forM_` 是惯用的 Haskell 吗？

Question

我倾向于在 Haskell 中使用 forM_，这很像 Ruby 中的 .each 或 Scala 中的 foreach。

import Control.Monad (forM_)
import Network.BSD (getHostByName, hostAddresses)
import Network.Socket (inet_ntoa)
import System.Environment (getArgs)

resolve address = do
  ent <- getHostByName address
  mapM inet_ntoa (hostAddresses ent)

main = do
  args <- getArgs
  args `forM_` (\address -> do
    ips <- resolve address
    ips `forM_` (\ip -> putStrLn $ address ++ "\t" ++ ip))

这对我来说似乎并不习惯，但使用 mapM_ 似乎很笨拙。有没有一种惯用的方式来重写这段代码？

Answer 1

是的，尽管您最好只使用来自Data.Foldable 的for_ :: (Foldable t, Applicative f) => t a -> (a -> f b) -> f ()。

同样通过使用它作为前缀（即普通函数），代码看起来像一个“普通的”命令式代码：

main = do
    args <- getArgs
    for_ args $ \address -> do
        ips <- resolve address
        for_ ips $ \ip -> putStrLn $ address ++ "\t" ++ ip

附： ApplicativeMonadic“遍历”的版本：

• mapM ~ traverse
• mapM_ ~ traverse_
• forM ~ for
• forM_ ~ for_

Answer 2

main = getArgs >>= mapM_ (\address ->
  resolve address >>= mapM_ (\ip ->
    putStrLn $ address ++ "\t" ++ ip))

一旦我们有了ArgumentDo，我们就不必将那个 lambda 表达式括起来。

ListT 也恰好适用：

main = void $ runListT $ do
  address <- ListT getArgs
  ip <- ListT $ resolve address
  liftIO $ putStrLn $ address ++ "\t" ++ ip