如何检测 DBGrid 或 ClientDataset 中的用户在运行时删除了单元格中的数据？

Question

我有一个程序需要由用户删除单元格中的数据来触发/触发。看起来 ClientDataset.Delete 不适合这种情况。

我的数据结构是：

TADOConnection -> TADOQuery -> TDataSetProvider -> TClientDataSet -> TDataSource -> TDBGRidEh (descendant of TDBGrid)

我是否需要创建一个过程来检测删除，或者是否已经有一个事件或属性可以用于此目的？

Answer 1

下面的代码应该检测到您的 CDS 的给定字段（在此示例中为 Customer）何时被修改，因此 其 AsString 属性为空字符串或字段的值已 设置为 Null，但在任何一种情况下，仅当该字段之前具有非 Null、非空值时。

它使用 TFieldDataLink 的自定义后代来进行检测和处理 dsFieldChange 事件。这只会在 Post 方法正在执行且尚未返回时立即触发。

type
  TMyFieldDataLink = class(TFieldDataLink)
    procedure DataEvent(Event: TDataEvent; Info: Integer); override;
  end;

type
  TForm1 = class(TForm)
    ClientDataSet1: TClientDataSet;
    DataSource1: TDataSource;
    DBGrid1: TDBGrid;
    ADOConnection1: TADOConnection;
    ADOQuery1: TADOQuery;
    DataSetProvider1: TDataSetProvider;
    DBNavigator1: TDBNavigator;
    DBEdit1: TDBEdit;
    procedure FormCreate(Sender: TObject);
  private
    FieldDataLink : TFieldDataLink;
  end;
[...]
procedure TForm1.FormCreate(Sender: TObject);
begin
  FieldDataLink := TMyFieldDataLink.Create;
  FieldDataLink.DataSource := DataSource1;
  FieldDataLink.FieldName := 'Company';
end;

{ TMyFieldDataLink }

procedure TMyFieldDataLink.DataEvent(Event: TDataEvent; Info: Integer);
var
  S : String;
  V : Variant;
begin
  inherited;

  if Event = deFieldChange then begin
    V :=  Field.OldValue;
    if not VarIsNull(V) then begin
      S := V;
      if (S <> '') and (Field <> Nil) and (Field.IsNull or (Field.AsString = '')) then begin
        ShowMessage('Field: ' + Field.FieldName + ' emptied');
      end;
    end;
  end;
end;

要使用、剪切并粘贴到新的 VCL 项目中。

顺便说一句，对于这样的问题，最好从数据集的角度而不是从 DBGrid 等特定组件的角度开始。