如何检测是否在多个彼此不相邻的单元格中删除了文本

Question

我想检测是否正在从一些彼此不相邻的单元格中删除文本/值，以便在发生这种情况时执行例程。

以我为例，如果文本已从这些单元格中删除，我想监视单元格 E5、E8、E11 和 E14。因此，如果 E5 已被删除，我想执行子程序 #1。如果 E8 已被删除，我想执行子程序 #2。子程序#1 和#2 不同。所有子例程都是独一无二的，因为我无法将 E5、E8、E11 和 E14 作为一个范围进行监控。

如果我向单元格添加文本，我不想执行例程 - 只有从单元格中删除内容才会触发子例程。

我只能按照以下例程进行 - 它无法正常工作，因为如果我添加文本或删除文本，它不会区分。我也不知道如何在不使用范围的情况下监控多个单元格？

' Private Sub Worksheet_Change(ByVal Target As Range)   
    If Target.Address = "$E$5" Then
    MsgBox "hello"
    End If
End Sub

有人可以指点我正确的方向吗？

非常感谢。

Answer 1

请尝试下一个方法：

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim rng As Range: Set rng = Range("E5")
  If Target.cells.Count > 1 Then Exit Sub
  If Not Intersect(Target, Union(rng, rng.Offset(3), rng.Offset(6), rng.Offset(9))) Is Nothing Then
    If Target.Value = "" Then
        Select Case Target.Address(0, 0)
            Case "E5": Debug.Print "E5 is empty" 'mySubrutine1
            Case "E8": Debug.Print "E8 is empty"
            Case "E11": Debug.Print "E11 is empty"
            Case "E14": Debug.Print "E14 is empty"
        End Select
    End If
 End If
End Sub

它只分析指定的单元格，只有当修改的单元格为空时才做一些事情。

在选择多个单元格的情况下退出。但是，它可以很容易地适应也接受多个删除。其实下一个变种应该可以处理这样的情况：

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim rng As Range, C As Range: Set rng = Range("E5")

  If Not Intersect(Target, Union(rng, rng.Offset(3), rng.Offset(6), rng.Offset(9))) Is Nothing Then
    For Each C In Target.cells
        If C.Value = "" Then
            Select Case C.Address(0, 0)
                Case "E5": Debug.Print "E5 is empty" 'mySubrutine1
                Case "E8": Debug.Print "E8 is empty" 'mySubrutine2
                Case "E11": Debug.Print "E11 is empty" 'mySubrutine3
                Case "E14": Debug.Print "E14 is empty" 'mySubrutine4
            End Select
        End If
    Next C
 End If
End Sub