Automator 应用程序中的 Applescript 不会拖放。一直要文件

Question

我正在使用 Automator 应用程序（拖放）来重命名一些文件。我想做的一件事是去掉 zip 文件的“从哪里来”。此脚本有效，除了它在运行时询问文件，而允许我将文件拖放到应用程序图标的顶部。

我做错了什么？如何使应用程序可拖放？

on deleteWhereFrom(fileToClean)
    try
        set posixPath to quoted form of POSIX path of fileToClean
        do shell script "xattr -d com.apple.metadata:kMDItemWhereFroms " & posixPath
    end try
end deleteWhereFrom
on open zip
    repeat with i in zip
        deleteWhereFrom(i)
    end repeat
end open
on run
    set zip to choose file with multiple selections allowed
    repeat with i in zip
        deleteWhereFrom(i)
    end repeat
end run

Answer 1

在 AppleScript 应用程序中，打开处理程序用于将项目拖放到 droplet 上。然而，在 Automator 应用程序中，拖放到应用程序上的项目被传递到工作流中的第一个操作，该操作执行它所做的任何事情并将其结果传递给工作流中的下一个操作，依此类推。

对于Run AppleScript动作，它的输入在run handler的input参数中，这是一个从前面动作传递过来的项目列表，当run handler完成它所做的一切时，返回结果是传递给以下操作的内容。

在您的原始示例中，问题在于 Run AppleScript 操作未使用工作流中传递的任何项目，而是使用 choose file 来请求要使用的项目（再次） .你的脚本应该是：

on run {input, parameters}
   repeat with i in input
      deleteWhereFrom(i)
   end repeat
   return input -- return the input items to any following actions
end run

on deleteWhereFrom(fileToClean)
   try
      set posixPath to quoted form of POSIX path of fileToClean
      do shell script "xattr -d com.apple.metadata:kMDItemWhereFroms " & posixPath
   end try
end deleteWhereFrom

请注意，根据您之前使用的任何操作，您可能需要在工作流开始时使用 Set Value of Variable 操作来保存原始项目（拖到应用程序上的项目），然后使用 @987654327 @action（根据需要设置其“忽略此操作的输入”选项）以获取这些原始项目，以便将它们传递给Run AppleScript 操作。