分配大尺寸数组时出现 System.OutOfMemoryException

Question

在我将文件上传到 FTP 网站的 vb 应用程序中，我使用大尺寸数组。在声明数组的过程中，有时我会收到Exception of type 'System.OutOfMemoryException' was thrown.

之类的错误

我已将数组声明为

Const BufferSize As Integer = 400000000
Dim content(BufferSize - 1) As Byte

实际上 400000000 大约是 380 MB 。我有 4 GB RAM，使用率不高。为什么有时会显示此错误？怎么解决？

Answer 1

参考我之前的same question 和answer（感谢Aik 的出色解释）。

即使您有 4gb 内存，也无法知道您有 380mb 的连续可用空间。如果您的 RAM 碎片太大，这可能会导致问题。

你需要丢弃你的数据来解决这个问题（见answer...）

AIK 的解释：

例如在我的机器上我不能分配超过 908 000 000 一个数组中的字节，但我可以分配 100 * 90 800 000 没有任何 如果它存储在更多数组中会出现问题：

Dim toBigArray As Byte() = New Byte(908000000) {}
'doesn't work (6 zeroes after 908)
' allocation in more arrays
Dim a As Byte()() = New Byte(100)() {}

For i As Integer = 0 To a.Length - 1
    ' it works even there is 10x more memory needed than before
        ' (5 zeroes after 908) 
    a(0) = New Byte(90800000) {}
Next

Answer 2

使用这么大的数组是个坏主意。您可以分小块流式传输文件。这是来自link的一些示例代码

''' <summary>
''' Methods to upload file to FTP Server
''' </summary>
''' <param name="_FileName">local source file name</param>
''' <param name="_UploadPath">Upload FTP path including Host name</param>
''' <param name="_FTPUser">FTP login username</param>
''' <param name="_FTPPass">FTP login password</param>

Public Sub UploadFile(ByVal _FileName As String, ByVal _UploadPath As String, ByVal _FTPUser As String, ByVal _FTPPass As String)
Dim _FileInfo As New System.IO.FileInfo(_FileName)

' Create FtpWebRequest object from the Uri provided
Dim _FtpWebRequest As System.Net.FtpWebRequest = CType(System.Net.FtpWebRequest.Create(New Uri(_UploadPath)), System.Net.FtpWebRequest)

' Provide the WebPermission Credintials
_FtpWebRequest.Credentials = New System.Net.NetworkCredential(_FTPUser, _FTPPass)

' By default KeepAlive is true, where the control connection is not closed
' after a command is executed.
_FtpWebRequest.KeepAlive = False

' set timeout for 20 seconds
_FtpWebRequest.Timeout = 20000

' Specify the command to be executed.
_FtpWebRequest.Method = System.Net.WebRequestMethods.Ftp.UploadFile

' Specify the data transfer type.
_FtpWebRequest.UseBinary = True

' Notify the server about the size of the uploaded file
_FtpWebRequest.ContentLength = _FileInfo.Length

' The buffer size is set to 2kb
Dim buffLength As Integer = 2048
Dim buff(buffLength - 1) As Byte

' Opens a file stream (System.IO.FileStream) to read the file to be uploaded
Dim _FileStream As System.IO.FileStream = _FileInfo.OpenRead()

Try
' Stream to which the file to be upload is written
Dim _Stream As System.IO.Stream = _FtpWebRequest.GetRequestStream()

' Read from the file stream 2kb at a time
Dim contentLen As Integer = _FileStream.Read(buff, 0, buffLength)

' Till Stream content ends
Do While contentLen <> 0
' Write Content from the file stream to the FTP Upload Stream
_Stream.Write(buff, 0, contentLen)
contentLen = _FileStream.Read(buff, 0, buffLength)
Loop

' Close the file stream and the Request Stream
_Stream.Close()
_Stream.Dispose()
_FileStream.Close()
_FileStream.Dispose()
Catch ex As Exception
MessageBox.Show(ex.Message, "Upload Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
End Try
End Sub


HOW TO USE:  

 ' Upload file using FTP
   UploadFile("c:\UploadFile.doc", "ftp://FTPHostName/UploadPath/UploadFile.doc", "UserName", "Password")

编辑 1：

试试这些链接可能对你有帮助。

1)My.Computer.Network.UploadFile

2)Improve Performance of FtpWebRequest