wget 从具有多个部分的多个 URL 下载多个文件

Question

在这里完成新手所以提前道歉。

基本上，我正在尝试尽可能多地自动化我的流程。我希望能够下载分成不同 .ts 部分（大约 150 个）的流式视频。

由于某种原因，使用 {0..150} 函数循环访问各个部分对我不起作用，因为它将字符串解释为 URL 的一部分，并返回 Not found 错误。 （可能是我通过 Windows cmd 运行 wget 吗？） 挖了一下，能够制定一个成功下载视频文件的脚本：

 setlocal enabledelayedexpansion
 @echo off
 set directory=https://URLstring/playlist
 for /l %%x in (0, 1, 150) do (
    set tsNum=%%x
    set num=%directory%!tsNum!
    set ts=.ts
    set file=!num!!ts!
    wget !file!
 )

但是，由于每周上传 10 个这样的视频（每个分为 150 个部分），我希望能够从 .txt 列表中提取这 10 个 URL。

我阅读了有关 wget 的 -i 函数的信息，但要么我的语法错误，要么我无法找到合并 2 个脚本的方法。

有人有什么建议吗？

Answer 1

如果您想将文件中的 url 读入目录变量而不是硬编码目录变量，那么您可以像这样更改脚本：

@echo off
setlocal enabledelayedexpansion
for /f "" %%a in (directory.txt) do (
    set directory=%%a
    for /l %%x in (0, 1, 150) do (
        set tsNum=%%x
        set num=!directory!!tsNum!
        set ts=.ts
        set file=!num!!ts!
        echo wget !file!
    )
)

如果您还想从文件中读取部分的数量，您可以将文件中的每一行作为 url 和由空格或制表符分隔的部分数量（这没关系，因为 url 不包含空格和制表符) 然后像这样更改您的脚本：

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,2" %%a in (directory.txt) do (
    set directory=%%a
    set parts=%%b
    for /l %%x in (0, 1, !parts!) do (
        set tsNum=%%x
        set num=!directory!!tsNum!
        set ts=.ts
        set file=!num!!ts!
        echo wget !file!
    )
)

就像@Squashman 所说，根本没有理由将值存储在环境变量中 - 您可以像这样直接使用 for 循环变量：

@echo off
for /f "tokens=1,2" %%a in (directory.txt) do (
    for /l %%x in (0, 1, %%b) do (
        echo wget %%a%%x.ts
    )
)

这是我用于测试的 directory.txt：

https://URLstring1/playlist 2
https://URLstring2/playlist 3
https://URLstring3/playlist 4

我在每一行中使用的第一个值是 URL，第二个是部分数。