R 语言：原始字符串的语法

Question

我正在尝试在 R 语法中为原始字符串创建一个新规则。

引用 R 新闻：

有一种用于指定原始字符常量的新语法，类似于 到 C++ 中使用的那个： r"(...)" with ... 任何字符序列不是 包含序列）”。这使得编写字符串变得更容易 包含反斜杠或单引号和双引号。更多细节 见？行情。

例子：

## A Windows path written as a raw string constant:
r"(c:\Program files\R)"

## More raw strings:
r"{(\1\2)}"
r"(use both "double" and 'single' quotes)"
r"---(\1--)-)---"

但我不确定仅一个语法文件是否足以实现该规则。 到目前为止，我尝试了类似语法的类似语法的旧建议：

解析器：

|   RAW_STRING_LITERAL #e42

词法分析器：

RAW_STRING_LITERAL
        : ('R' | 'r') '"' ( '\\' [btnfr"'\\] | ~[\r\n"]|LETTER )* '"' ; 

感谢任何提示或建议。

R ANTLR 语法：

https://github.com/antlr/grammars-v4/blob/master/r/R.g4

Bison 中的原始 R 语法：

https://svn.r-project.org/R/trunk/src/main/gram.y

Answer 1

要匹配开始和结束分隔符，您必须使用特定于目标的代码。在 Java 中可能如下所示：

@lexer::members {
  boolean closeDelimiterAhead() {
    // Get the part between `r"` and `(`
    String delimiter = getText().substring(2, getText().indexOf('('));

    // Construct the end of the raw string
    String stopFor = ")" + delimiter + "\"";

    for (int n = 1; n <= stopFor.length(); n++) {
      if (this._input.LA(n) != stopFor.charAt(n - 1)) {
        // No end ahead yet
        return false;
      }
    }

    return true;
  }
}

RAW_STRING
 : [rR] '"' ~[(]* '(' ( {!closeDelimiterAhead()}? . )* ')' ~["]* '"'
 ;

将r"---( )--" )----" )---" 标记为单个RAW_STRING。

编辑

由于分隔符只能由连字符（和括号/大括号）组成，而不仅仅是任意字符，因此也应该这样做：

RAW_STRING
 : [rR] '"' INNER_RAW_STRING '"'
 ;

fragment INNER_RAW_STRING
 : '-' INNER_RAW_STRING '-'
 | '(' .*? ')'
 | '{' .*? '}'
 | '[' .*? ']'
 ;