Neo4j 查询多跳

Question

大家好，我正在尝试编写一个 neo4j 查询来获得多个跃点。

目前我的架构是 作者 - fname,lname & 论文 - 标题

关系：作者 -> 写过 -> 论文

MATCH (a:Author)-[:WROTE]->(p:Paper)
WITH a as auth1, count(p.title) as count1
MATCH (auth1) -[:WROTE *1]->(p2:Paper),
              (auth2)-[:WROTE *1]->(p2)
WHERE count1 > 7
RETURN DISTINCT auth1.fname, auth1.lname, auth2.fname,  auth2.lname

我要做的是找到所有与我的作者相关的人，他们撰写的论文最多 - 首先是 1 跳，然后是 2 跳等。我知道论文最多的作者写了 8 篇，因此我的计数 > 7 ;但是我认为我的查询不正确。每当我改变

:WROTE *1 to :WROTE *1..2

结果与我认为不应该的结果相同 - 任何帮助将不胜感激

Answer 1

[编辑]

下面是一个查询，不需要事先知道您最有成效的作者（共同）撰写了多少篇论文。它会自动确定该作者是谁，然后找到他/她的所有合著者及其合著者。为此，-[:WROTE*..3]- 模式是无方向的，并使用上限 3（因为要到达共同作者的共同作者，需要跳 3 次关系）。一般来说，如果您希望共同作者的深度为 N，则需要上限为 (1+(N-1)*2)。

MATCH (auth1:Author)-[:WROTE]->(p:Paper)
WITH auth1, COUNT(p) AS count1
ORDER BY count1 DESC LIMIT 1
MATCH (auth1)-[:WROTE]->(:Paper)-[:WROTE*..3]-(auth2:Author)
RETURN DISTINCT auth1.fname, auth1.lname, auth2.fname,  auth2.lname;

此外，如果您想在 neo4j 浏览器中可视化所有感兴趣的共同作者及其共同撰写的论文，这应该可行：

MATCH (auth1:Author)-[:WROTE]->(p:Paper)
WITH auth1, COUNT(p) AS count1
ORDER BY count1 DESC LIMIT 1
MATCH path=(auth1)-[:WROTE]->(:Paper)-[:WROTE*..3]-(auth2:Author)
WITH auth1, auth2, NODES(path) AS ns
RETURN DISTINCT auth1, auth2, [i IN RANGE(1, SIZE(ns)-1, 2) | ns[i]] AS papers

RANGE(1, SIZE(ns)-1, 2) 返回每​​个path 中Paper 节点的索引列表（因为它们具有奇数索引）。

确保禁用Browser Settings 中的Connect result nodes 选项，否则可视化可能会显示结果中没有的额外节点。