Neo4j 多关系查询

Question

我正在使用 Neo4j 做一个学校项目，但遇到了问题。我想通过他们的 ID 或索引号获取所有已申请参加考试并参加任何考试或注册的学生。我将学生和科目与考试联系起来，这是与属性 (STUDENT)-[EXAM]-(SUBJECT) 和/或 (STUDENT)-[REGISTRATION]-(EXAM) 的关系。 我需要 1 个学生的 id，该学生与 1 个查询中的主题的所有连接。 数据库如下所示：

MERGE (std5:STUDENT { name:'Nola', surname:'Joan', indexnumber:12000, semester:'I' })
MERGE (std4:STUDENT { name:'Pola', surname:'Moan', indexnumber:12001, semester:'II' })

MERGE (sub1:SUBJECT { name:'Databases', semester:'VII' })
MERGE (sub2:SUBJECT { name:'Advanced Databases', semester:'VIII' })

MERGE (std5) - [ :EXAM { signed:' ' , mark:6 , date:'12.01.2017.' }] -> (sub1)//mark 6 is passing
MERGE (std4) - [ :EXAM { signed:' ' , mark:5 , date:'12.01.2017.' }] -> (sub1)

MERGE (std5) - [ :REGISTRATION {date:"2/11/2015", charge:0,  term:'June'}] -> (sub1)

MERGE (std5) - [ :REGISTRATION {date:"2/11/2016", charge:0,  term:'June'}] -> (sub1)

MERGE (std4) - [ :REGISTRATION {date:"2/11/2015", charge:0,  term:'June'}] -> (sub2)

我使用的查询是这个，但给了我双倍的数据，而且经常是错误的。我需要一个特定的学生获得所有这些考试的所有考试和注册，这样我就可以得到一份完整的列表，其中列出了谁以及何时参加和/或通过了考试、已注册，或者他是否从未注册和参加过考试。

OPTIONAL MATCH (p:STUDENT) - [d:EXAM] - (c:SUBJECT)

WHERE p.indexnumber = 12000  and d.mark<5 //failing grade

WITH collect (distinct c) as c1,d

OPTIONAL MATCH (p:STUDENT) - [b11:EXAM] - (c:SUBJECT)

WHERE p.indexnumber = 12000

WITH p , count(c) as rels, collect(b11) as exams,d,collect(distinct c +c1) as c2

RETURN p, c2, d, rels , exams

总而言之，学生是通过注册或考试或两者联系起来的，我需要为该学生获取索引号的所有这些关系。然后计算所有这些与科目的关系，因为学生参加考试的次数数据保存在与所述科目的关系考试中。此外，所有分数

Answer 1

我还没有完全理解您的要求，但有几点建议：

• 使用MATCH 子句选择学生一次，然后再使用该变量。
• 您可以通过在 MATCH 子句中包含 {indexnumber: 12000} 来缩短代码，而不是在 WHERE 中添加条件。
• 使用collect(distinct c + c1) 会为每个c 元素包含c1 集合，这可能不是您想要的。

所以，为了收集失败和成功的考试以及注册信息，我会运行这样的查询（根据 InverseFalcon 的建议进行更新）：

MATCH (p:STUDENT {indexnumber: 12000})
OPTIONAL MATCH (p) - [e1:EXAM] -> (c1:SUBJECT)
WHERE e1.mark < 5
WITH p, collect(e1) AS failedExams
OPTIONAL MATCH (p) - [e2:EXAM] -> (c2:SUBJECT)
WHERE e2.mark >= 5
WITH p, failedExams, collect(e2) AS successfulExams
OPTIONAL MATCH (p) - [e3:REGISTRATION] -> (c3:SUBJECT)
RETURN failedExams, successfulExams, collect(e3) AS examRegistrations