将别名记录数组传递给过程

Question

在 Ada 2012 中，我希望在声明的数组内有一个链表，而不是分配。我想通过一个过程设置链接指针。

我已将我的程序简化为以下说明我想使用的原理，但我无法在 Raspi 上运行的 Gnat 4.9.2 (Debian Jessie) 中编译它...

procedure Arr is
   type Cell;
   type Cell_Ptr is access all Cell;

   type Cell is
      record
         Number : Integer := 0;
         Next : Cell_Ptr := null;
      end record;

   type Chain is array (1 .. 100) of aliased Cell;

   procedure Make_Links (Ch : in out Chain);

   procedure Make_Links (Ch : in out Chain) is
   begin
      for I in Ch'First .. Ch'Last - 1 loop
         Ch (I).Next := Ch (I + 1)'Access;                 -- ERROR HERE
      end loop;
   end Make_Links;

   My_Chain : Chain;
begin
   Make_Links (My_Chain);
end Arr;

我得到这个编译器错误： “non-local pointer cannot point to local object”在上面指出的那一行。

我知道我正在尝试做一些有点奇怪的事情，但我计划根据我将这个单元格数组传递给哪个过程以不同的方式（向后或随机等）执行链接的其他一些函数。

如何修复此代码以使其编译？无法完全理解这一点（我还是个新手，但很享受学习过程）。

Answer 1

由于您实际上并没有分配和释放内存，因此看不到指针的需要。我会通过执行以下操作来实现相同的功能：

procedure Arr is

   type Cell_Index is new Integer range 0 .. 100;
   subtype Valid_Cell_Index is Cell_Index range 1 .. Cell_Index'Last;

   type Cell is
      record
         Number : Integer := 0;
         Next   : Cell_Index := 0;
      end record;

   type Chain is array (Valid_Cell_Index) of Cell;

   procedure Make_Links (Ch : in out Chain);

   procedure Make_Links (Ch : in out Chain) is
   begin
      for I in Valid_Cell_Index'First .. Valid_Cell_Index'Last - 1 loop
         Ch (I).Next := I+1;
      end loop;
   end Make_Links;

   My_Chain : Chain;
begin
   Make_Links (My_Chain);

end Arr;

这样您仍然使用 Next 作为同一数组的索引，并且可以使用您想要的任何链接模式预加载您的数组。

Answer 2

不要使用’Access，而是使用’Unrestricted_Access。这是one of GNAT’s “implementation-defined” attributes：

Unrestricted Access 属性与 Access 相似，只是省略了所有可访问性和别名视图检查。这是一个用户注意的属性。

Answer 3

最后我想通了。以下代码是 OP 中的代码的修改版本。它做了我最初想要的，没有做任何不愉快的事情......

with Ada.Integer_Text_IO, Ada.Text_IO;
use Ada.Integer_Text_IO, Ada.Text_IO;

procedure Arr is
   type Cell;
   type Cell_Ptr is access all Cell;

   type Cell is
      record
         Number : Integer := 0;
         Next : Cell_Ptr := null;
      end record;

   type Chain is array (1 .. 100) of aliased Cell;
   type Chain_Ptr is access all Chain;

   procedure Make_Links (CP : in out Chain_Ptr);

   procedure Make_Links (CP : in out Chain_Ptr) is
   begin
      for I in CP'First .. CP'Last - 1 loop
         CP.all (I).Next := CP.all (I + 1)'Access;
      end loop;
   end Make_Links;

   My_Chain : aliased Chain;
   My_CP : Chain_Ptr := null;
   My_C : Cell_Ptr := null;
begin
   My_CP := My_Chain'Access;
   Make_Links (My_CP);

   --  verify that the code works by writing values into the array
   for I in My_Chain'Range loop
      My_Chain (I).Number := 1000 * I;
   end loop;

   --  and read them back out using the pointer links
   My_C := My_Chain (My_Chain'First)'Access;
   while My_C /= null loop
      Put (My_C.Number);
      Put_Line ("");
      My_C := My_C.Next;
   end loop;

end Arr;

我没有直接传递数组，而是传递了一个指向数组的指针，Gnat 似乎对此很满意。我认为我之前尝试做的事情被过程参数的“通过复制”规则所破坏。