CDec：带小数的参数字符串的国际语法

Question

我的 Excel 的所有内容（公式、界面、指南）都设置为英文。 我的 Windows 设置为“，”作为十进制符号和“。”用于区域设置中的数字分组符号，因为我住在意大利。

如果我写这段代码：

    Dim v As Variant
    v = CDec("12345678901234567000,123456789")
    v = v + 50

结果在 Locals 窗口中显示为“12345678901234567050,123456789”（变量/十进制）。如果我使用 msgbox 也一样。

如果我使用“。”而不是“，”，结果是 12345678901234567000123456839。

在 VBA 中，当写数字时（以数字的形式，而不是字符串），我必须使用英文语法，即“。”用于十进制符号。

我相信我的示例代码会在具有英语区域设置的 Windows 上错误地运行。

我怎样才能（修改它以）使其在任何区域设置下都能正常运行？

Answer 1

C* 转换函数（CInt、CLng、CStr 等）都设计为在计算机的当前区域设置中工作。他们将使用当前的小数分隔符，因此您正确地假设 CDec 将无法在具有不同小数点的系统上正确处理硬编码的 ,。

相反，Str 和 Val 始终使用英文分隔符，但它们不支持 Decimal。

---

所以想到的一种选择是获取小数点at runtime：

Dim v As Variant
v = CDec("12345678901234567000" & Application.International(xlDecimalSeparator) & "123456789")

但是应该注意，如果Application.UseSystemSeparators 是False 并且Application.DecimalSeparator 已更改，那么Application.International(xlDecimalSeparator) 将return that changed separator，而不是来自计算机区域设置的那个。所以如果你不能保证UseSystemSeparators就是True，就不要使用这个方法。

---

另一种选择是以十的幂除的形式表示小数位，这对于精确的定点Decimal数据类型很好：

Dim v As Variant
v = CDec("12345678901234567000123456789") / CDec("1000000000")

---

另一种选择是有一个自定义的“CDec”，它在特定的语言环境中明确工作，并始终在该语言环境中对字符串进行硬编码：

Option Explicit

#If VBA7 Then
Private Declare PtrSafe Function VarDecFromStr Lib "OleAut32.dll" (ByVal strIn As LongPtr, ByVal lcid As Long, ByVal dwFlags As Long, ByRef pdecOut As Variant) As Long
#Else
Private Declare Function VarDecFromStr Lib "OleAut32.dll" (ByVal strIn As Long, ByVal lcid As Long, ByVal dwFlags As Long, ByRef pdecOut As Variant) As Long
#End If

Private Const LOCALE_INVARIANT As Long = &H7F&
Private Const S_OK As Long = &H0

Public Function ParseDecimalFromEnUsString(ByVal s As String) As Variant
  Dim hr As Long

  hr = VarDecFromStr(StrPtr(s), LOCALE_INVARIANT, 0, ParseDecimalFromEnUsString)

  If hr <> S_OK Then
    Err.Raise 5, , "Cannot parse the string. Error " & Hex$(hr)
  End If
End Function

? ParseDecimalFromEnUsString("12345678901234567000.123456789")
12345678901234567000,123456789

? TypeName(ParseDecimalFromEnUsString("12345678901234567000.123456789"))
Decimal

（有关对what the string is allowed to contain 有更多控制权的此代码版本，请参阅此答案的revision 3。接收NUMPRS_STD 的参数是要更改的参数。）