如何将节点的属性与 xslt 1.0 中所有先前兄弟节点的属性进行比较？ （无钥匙）

Question

我有以下 XML 文件。

<?xml version="1.0" encoding="UTF-8"?>

<goods>
    <item class="fruit">apple</item>
    <item class="fruit">pineapple</item>
    <item class="vegetables">tomato</item>
    <item class="fruit">lemon</item>
    <item class="fruit">melon</item>
    <item class="fruit">orange</item>
    <item class="vegetables">cucumber</item>
    <item class="vegetables">onion</item>
    <item class="vegetables">garlic</item>
</goods>

我需要从中获取（但不使用密钥或 Muenchian 方法）XML，如下所示：

<fruit>
    <item class="fruit">apple</item>
    <item class="fruit">lemon</item>
    <item class="fruit">melon</item>
    <item class="fruit">orange</item>
    <item class="fruit">pineapple</item>
</fruit>
<vegetables>
    <item class="vegetables">cucumber</item>
    <item class="vegetables">garlic</item>
    <item class="vegetables">onion</item>
    <item class="vegetables">tomato</item>
</vegetables>

如您所见，我需要根据它们的类属性对项目进行分组（并作为额外的按字母顺序对它们进行排序，但现在这不是必需的）。

我的 XSLT 是：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="/">
        <xsl:for-each select="/*/*">
            <xsl:sort select="@class"/>
            <xsl:sort select="." order="ascending"/>
            <xsl:choose>
                <xsl:when test="position() = 1">
                    <xsl:apply-templates select="."/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:variable name="p" select="position()"/>
                        <xsl:if test="./@class != ./preceding-sibling::*[1]/@class">
                            <xsl:apply-templates select="."/>
                        </xsl:if>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each>
    </xsl:template>

    <xsl:template match="/*/*">
        <xsl:variable name="id" select="@class"/>

        <xsl:element name="{$id}">
            <xsl:copy-of select="." />
            <xsl:for-each select="following-sibling::*[@class = $id]">
                <xsl:sort select="." order="ascending"/>
                <xsl:copy-of select="." />
            </xsl:for-each>
        </xsl:element>
    </xsl:template>

</xsl:stylesheet>

不幸的是，使用这段代码我没有得到预期的结果。 我不明白的是如何将节点的属性与所有前面兄弟的属性进行比较。我试着这样做：

<xsl:if test="./@class != ./preceding-sibling::*/@class">

但它没有用。所以我尝试了这种方式：

<xsl:if test="./@class != ./preceding-sibling::*[1]/@class">

但当然它只与前一个兄弟比较，所以这也不是正确的代码。

也许有人可以帮助我解决这个问题？任何帮助将不胜感激。

提前非常感谢！

Answer 1

我不明白您为什么不使用密钥或 Muenchian 方法，但如果必须，您可以通过以下方式简单地（尽管效率低下！）：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/goods">
    <xsl:copy>
        <xsl:for-each select="item[not(@class = preceding-sibling::item/@class)]">
            <xsl:sort select="@class"/>
            <xsl:element name="{@class}">
                <xsl:for-each select="../item[@class = current()/@class]">
                    <xsl:sort/>
                    <xsl:copy-of select="."/>
                </xsl:for-each>
            </xsl:element>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

请注意，这取决于 class 属性的值是有效的元素名称。

---

如果它不会打扰你，你能否解释一下 2 个 Xpath 表达式 你用过：'item[not(@class= previous-sibling::item/@class)]' 和 '../item[@class= current()/@class]'.

item[not(@class = preceding-sibling::item/@class)]

选择任何class 不同于前面任何item 的item - 因此只选择不同的项目。我很惊讶你问这个问题，因为它完全按照你的问题标题中所说的那样做。

../item[@class = current()/@class]

选择任何class 等于当前的item - 因此选择了所有当前组中的项目。

另请参阅：http://www.jenitennison.com/xslt/grouping/muenchian.html，该方法与更有效的 Muenchian 方法一起解释。