如何使用 Perl 和 OLE 在 Excel 中打开制表符分隔的文本文件？

Question

最初我试图用 Excel 打开一个 XML 文件。但由于这需要很长时间，我自己将 XML 解析为制表符分隔的文本文件。我以为我在互联网上找到了正确的语法。我使用 Excel 宏记录的值尝试了下面的代码。我有一个 18 列制表符分隔的文件。调用“Worksheets”方法时，下面代码最后一行出现错误。

错误信息： 无法在 ./PostProcessingDev.pl 第 70 行调用没有包或对象引用的方法“Worksheets”。

use Win32::OLE;
use Win32::OLE::Const 'Microsoft Excel';
Win32::OLE->Option(Warn => 3);

use strict;

my $Excel;
my $Sheet;
my $Workbook;


$Excel = CreateObject OLE "Excel.Application";

$Workbook =  $Excel->Workbooks->OpenText({Filename =>"$inSelf->{'TXT'}",
  Origin => xlMSDOS,
  StartRow => 1,
  DataType => xlDelimited, 
  TextQualifier => xlDoubleQuote, 
  ConsecutiveDelimiter => "False", 
  Tab => "True",
  Semicolon => "False",
  Comma => "False",
  Space => "False",
  Other => "False",
  FieldInfo => [[1, xlTextFormat],
    [2, xlTextFormat],
    [3, xlTextFormat],
    [4, xlTextFormat],
    [5, xlTextFormat],
    [6, xlTextFormat],
    [7, xlTextFormat],
    [8, xlTextFormat],
    [9, xlTextFormat],
    [10, xlTextFormat],
    [11, xlTextFormat],
    [12, xlTextFormat],
    [13, xlTextFormat],
    [14, xlTextFormat],
    [15, xlTextFormat],
    [16, xlTextFormat],
    [17, xlTextFormat],
    [18, xlTextFormat]],
  TrailingMinusNumbers => "True"});

$Sheet = $Workbook->Worksheets(1);

Answer 1

您真的必须使用 Excel 解析 TSV 吗？如果你的文件中没有什么花哨的东西，你可能会使用这样的东西：

my $file = 'some tsv file';
{
    open my $in,"<",$file  or die "$file: $!";
    while(<$in>) {
        chomp;
        my @cols = split /\t/;
        # do something with columns in @cols array
    }
}

如果由于我看不到的原因需要 Excel，问题是 OpenText 方法返回 True/False 而不是 Workbook 对象。这有效：

use strict;

use Win32::OLE;
use Win32::OLE::Const 'Microsoft Excel';
use Data::Dump;     # for dd

Win32::OLE->Option(Warn => 3);

my $Excel = Win32::OLE->new("Excel.Application");
$Excel->Workbooks->OpenText({
    Filename             => 'enter the full path to file',
    Origin               => xlMSDOS,
    StartRow             => 1,
    DataType             => xlDelimited,
    TextQualifier        => xlDoubleQuote,
    Tab                  => "True",
    TrailingMinusNumbers => "True"
});

my $Sheet = $Excel->ActiveWorkbook->Worksheets(1);
my $Data = $Sheet->UsedRange()->{Value};

dd $Data;    # arrayref (rows) of arrayrefs (columns)

Answer 2

尝试使用Text::CSV。 它支持用户定义的分隔符。见模块说明。

Answer 3

非常感谢您的回答。这解决了我的问题。我想要对 OpenText 方法做的只是将 TSV 文件转换为 Excel，因为这是我需要的结果格式。因为在提供完整代码之前我无法在网上找到解决方案：

use Win32::OLE;
use Win32::OLE::Const 'Microsoft Excel';
use strict;

Win32::OLE->Option(Warn => 3);

my $FileName = "Complete Path of TSV File";

my $Excel = Win32::OLE->new("Excel.Application");

# Open Tab separated Text file in Excel, all 18 columns are "Text" formated
$Excel->Workbooks->OpenText({
  Filename      => $FileName,
  Origin        => xlMSDOS,
  StartRow      => 1,
  DataType      => xlDelimited,
  TextQualifier => xlDoubleQuote,
  Tab           => "True",
  FieldInfo     => [[1, xlTextFormat],
    [2, xlTextFormat],
    [3, xlTextFormat],
    [4, xlTextFormat],
    [5, xlTextFormat],
    [6, xlTextFormat],
    [7, xlTextFormat],
    [8, xlTextFormat],
    [9, xlTextFormat],
    [10, xlTextFormat],
    [11, xlTextFormat],
    [12, xlTextFormat],
    [13, xlTextFormat],
    [14, xlTextFormat],
    [15, xlTextFormat],
    [16, xlTextFormat],
    [17, xlTextFormat],
    [18, xlTextFormat]],
  TrailingMinusNumbers => "True"
});

my $Sheet = $Excel->ActiveWorkbook->Worksheets(1);
$Sheet->Activate;

my $Workbook = $Excel->ActiveWorkbook;

# Replace the "*.txt" file extension by "*.xls" for Excel
$FileName =~ s/txt$/xls/;

# Turn off the "This file already exists" message.
$Excel->{DisplayAlerts} = 0;
# Save file as Excel 2000-2003 Workbook (command for Excel 2007)
$Workbook->SaveAs({Filename => $FileName, FileFormat => xlExcel8});
$Excel->Quit;