金属计算着色器：将 alpha 设置为零不会产生完全透明

Question

我正在尝试修改这个人的代码：

https://github.com/FlexMonkey/MetalVideoCapture

它从 iphone / ipad 摄像头中获取视频，并使用一些 Metal GPU 计算内核实时对其进行过滤。

我想更改 Metal 代码以进行一些简单的色度键控，我们使视频中的某种颜色透明（即该颜色的 alpha = 0）。

问题在于，从金属计算内核输出的结果视频永远不会达到完全透明，即使您在金属计算内核结束时将 alpha 强制为零：

outTexture.write(float4(float3(rgb), 0.0), gid);

生成的视频只是部分透明。

请注意，我正在设置 layer.opaque = false 对于正在渲染的 MTKView。

有人知道为什么会这样吗？

这是 alpha = 0 和 UIView 的红色背景的结果：

所以哥伦布的回答对我有用，这里是我的色键过滤器的代码：

kernel void ChromaKey(texture2d<float, access::read> yTexture [[texture(0)]],
                                   texture2d<float, access::read> cbcrTexture [[texture(1)]],
                                   texture2d<float, access::write> outTexture [[texture(2)]],
                                   uint2 gid [[thread_position_in_grid]])
{
    float2 green = float2(54.0/255.0, 34.0/255.0);
    float threshold = 0.05;
    float3 colorOffset = float3(-(16.0/255.0), -0.5, -0.5);
    float3x3 colorMatrix = float3x3(
                                    float3(1.164,  1.164, 1.164),
                                    float3(0.000, -0.392, 2.017),
                                    float3(1.596, -0.813, 0.000)
                                    );

    uint2 cbcrCoordinates = uint2(gid.x / 2, gid.y / 2);
    float y = yTexture.read(gid).r;
    float2 cbcr = cbcrTexture.read(cbcrCoordinates).rg;
    float alpha = smoothstep(threshold, threshold + 0.5, distance(cbcr, green));
    float3 ycbcr = float3(y, cbcr);
    float4 rgba = alpha * float4(colorMatrix * (ycbcr + colorOffset), 1.0);
    outTexture.write(rgba, gid);
}

Answer 1

我的猜测是您的图层正在使用预乘 alpha (mentioned here)。如果是这种情况，那么您有两个简单的解决方案：

1. 将图层从预乘 Alpha 合成更改为使用非预乘 Alpha 合成。
2. 更改计算内核以执行 alpha 预乘。

要执行 #2，您需要进行如下更改：

float alpha = <something_or_other>;
float3 rgb = colorMatrix * (ycbcr + colorOffset);
outTexture.write(float4(float3(rgb), alpha), gid);

这样的：

float alpha = <something_or_other>;
float3 rgb = (colorMatrix * (ycbcr + colorOffset)) * alpha;
outTexture.write(float4(float3(rgb), alpha), gid);