OnAction 带参数

Question

这是我有史以来第一个关于 SO 的问题，即使我经常来这里（直到今天我一直都能找到答案）。我知道我已经发布了这个问题，但由于某种原因我不适合我。

我正在尝试获得一个右键单击子菜单，其中包含我的 word 文档中每个编号的项目的列表。它的目的是在我的文档中插入我的编号项目的编号和内容文本。

问题是我不知道如何影响每个 .OnAction（在我的文档中插入编号的项目）和每个 .Caption（在我的菜单中显示我的编号项目的编号和内容文本）具有不同的变量（每个编号的项目一个）。我的报价可能有问题，但我看不到任何其他解决方案。

我的代码如下：

Option Explicit

Sub ControlButtonNumberedItems()

'Parameters for NumberedItems
Dim i As Integer
i = 1
Dim NumberedItems As Integer
NumberedItems = ActiveDocument.CountNumberedItems

'Parameters for CommanBar
Dim MenuButton As CommandBar
Set MenuButton = Application.CommandBars("Text")
Dim SubMenuButton As CommandBarControl
Set SubMenuButton = MenuButton.Controls.Add(Type:=msoControlPopup, Before:=1)

With SubMenuButton
    .Caption = "NumberedItems"
    .Tag = "My_Tag"

    While i <= NumberedItems
        With .Controls.Add(Type:=msoControlButton)
            .OnAction = "'InsertNumberedItem""i""'"
            .FaceId = 38
            .Caption = "MyCaption"
        End With
        i = i + 1
    Wend

End With

End Sub

Sub InsertEvidence(i As Integer)

'Insert NumberRelativeContext
Selection.InsertCrossReference ReferenceType:=wdRefTypeNumberedItem, _
ReferenceKind:=wdNumberRelativeContext, _
ReferenceItem:=i, _
InsertAsHyperlink:=True, _
SeparatorString:=" "

Selection.TypeText Text:=" "

'Insert ContentText
Selection.InsertCrossReference ReferenceType:=wdRefTypeNumberedItem, _
ReferenceKind:=wdContentText, _
ReferenceItem:=i, _
InsertAsHyperlink:=True, _
SeparatorString:=" "

'Text form
Selection.Expand Unit:=wdLine
Selection.Font.Bold = wdToggle
Selection.Font.Italic = wdToggle
Selection.ParagraphFormat.Alignment = wdAlignParagraphRight
Selection.ParagraphFormat.SpaceBefore = 6

End Sub

Sub ResetRightClick()
Application.CommandBars("Text").Reset 
End Sub

提前感谢您的帮助。如果您需要任何其他信息，请告诉我。

Answer 1

我不知道 Word VBA 与 Excel 不同：在此处查看接受的答案：

VBA Pass arguments with .onAction

这对我有用（只是显示如何传递参数所需的代码）：

Sub ControlButtonNumberedItems()

    Dim i As Integer
    Dim NumberedItems As Integer

    'Parameters for CommanBar
    Dim MenuButton As CommandBar
    Set MenuButton = Application.CommandBars("Text")
    Dim SubMenuButton As CommandBarControl
    Set SubMenuButton = MenuButton.Controls.Add(Type:=msoControlPopup, Before:=1)

    With SubMenuButton
        .Caption = "NumberedItems"
        .Tag = "My_Tag"

        For i = 1 To 5
            With .Controls.Add(Type:=msoControlButton)
                .OnAction = "InsertNumberedItem"
                .FaceId = 38
                .Parameter = i
                .Caption = "MyCaption " & i
            End With
        Next i

    End With

End Sub

Public Sub InsertNumberedItem()
    MsgBox "got " & CommandBars.ActionControl.Parameter
End Sub

Sub ResetRightClick()
    Application.CommandBars("Text").Reset
End Sub