在DOSBOX中检测QB45中的ANSI答案

【问题标题】：Detect ANSI in QB45 in DOSBOX在DOSBOX中检测QB45中的ANSI
【发布时间】：2026-01-15 16:25:01
【问题描述】：

我一直在使用 DOSbox 和 ANSI 并取得了一些成功，但我想检测是否安装了 ANSI。

检测ANSI的Ralf Brown描述为：

--------V-2F1A00-----------------------------
INT 2F - DOS 4.0+ ANSI.SYS - INSTALLATION CHECK
    AX = 1A00h
Return: AL = FFh if installed
Notes:  AVATAR.SYS also responds to this call
   documented for DOS 5+, but undocumented for DOS 4.x

而我检测 ANSI 的代码是：

' detect ansi
InregsX.AX = &H1A00
CALL InterruptX(&H2F, InregsX, OutregsX)
PRINT "AX="; HEX$(OutregsX.AX)
IF (OutregsX.AX AND &HFF) = &HFF THEN
   Ansi.Installed = -1
ELSE
   Ansi.Installed = 0
END IF
IF Ansi.Installed THEN
   PRINT "Ansi installed."
ELSE
   PRINT "Ansi not installed."
END IF

始终显示“Ansi 未安装”。还有其他方法可以检测ANSI吗？？

【问题讨论】：

标签： ansi dosbox quickbasic

【解决方案1】：

我认为您可能会解决尝试使用 ANSI 代码的问题。

下面的代码实现了函数ansiOn%，如果按预期在屏幕上（用作控制台：参见代码）写入ansi字符串，则返回1，否则返回0。

该函数实现的方法是清屏并写入一个字符串，该字符串包含：与A$不同的第一个字符、1个字符的反向ANSI序列-CSI 1 D-和A$的内容。字符串写入后，如果屏幕左上角的字符为A$，则启用ANSI。

DECLARE FUNCTION ansiOn% ()

ansi% = ansiOn%
CLS

PRINT "ANSI is";
IF ansi% = 0 THEN
  PRINT "n't";
END IF

PRINT " enabled."

FUNCTION ansiOn%

  CLS : A$ = "C"
  OPEN "CON" FOR OUTPUT AS #1
  PRINT #1, CHR$(ASC(A$) - 1); CHR$(27); "[1D"; A$;
  CLOSE #1

  IF CHR$(SCREEN(1, 1)) = A$ THEN
    ansiOn% = 1
  ELSE
    ansiOn% = 0
  END IF

END FUNCTION

我在 DOS 6.22 VM 中使用 QB45 尝试了这段代码，它可以工作。

【讨论】：

我不得不将 OPEN "CON" 修改为 OPEN "CONS:"
同样的事情可以用 [2J
奇怪的是你必须在原始 DOS 6.22 下的 VM 中更改 OPEN "CONS:" 中的 OPEN "CON" 是正确的（但也是 OPEN "CONS:"）...
无论如何，我阅读了 QB$5 帮助并报告“CONS:” ;) ... 可能 CON 是 DOS 设备规范，而 DOSBOX 不支持它。

【解决方案2】：

我写了这段代码来检测 ANSI：

Cls
Const A$ = "alpha"
Const B$ = "beta"
Open "CONS:" For Output As #1
Print #1, A$
Z$ = Chr$(27) + "[2J" ' ansi cls
Print #1, Z$; B$;
Close #1
For T = 1 To Len(B$)
   T$ = T$ + Chr$(Screen(1, T))
Next
If T$ = B$ Then Print "ANSI detected."

【讨论】：

顺便说一句：QB64 没有缺点：支持，只有 SCRN：