在 Haskell 中对类型 a 使用排序时出错

Question

我对 Haskell 很陌生，我正在尝试编写一个函数 neighbours :: Int -> Metric a -> Point a -> [Point a] -> [Point a] 以便 neighbours k d p xs 返回 k 个最近邻居的列表，按照距离顺序，根据度量 d 到列表 xs 中的点 p点。我的代码是

type Point a = (a, a)
type Metric a = Point a -> Point a -> Double
type Tuple a = (Double, Point a)

create:: Metric a -> Point a -> [Point a] ->  [Tuple a] -> [Tuple a]
create d p (x:xs) ys | length xs == 0 = sort(((d p x), x) : ys)
                     | otherwise      = create d p xs (((d p x), x) : ys)

takeP:: Tuple a -> Point a
takeP (_,p) = p   

pList::  [Tuple a] ->[Point a]-> [Point a]
pList (x:xs) ys | length xs == 0 = reverse (takeP x : ys)
                | otherwise      = pList xs (takeP x : ys) 

neighbours :: Int -> Metric a -> Point a -> [Point a] -> [Point a]--
neighbours k d p xs = take k (pList (create d p xs []) [])

但我在排序时遇到错误：

* No instance for (Ord a) arising from a use of `sort'
  Possible fix:
    add (Ord a) to the context of
      the type signature for:
        create :: forall a.
                  Metric a -> Point a -> [Point a] -> [Tuple a] -> [Tuple a]
* In the expression: sort (((d p x), x) : ys)
  In an equation for `create':
      create d p (x : xs) ys
        | length xs == 0 = sort (((d p x), x) : ys)
        | otherwise = create d p xs (((d p x), x) : ys)

我一开始使用type Point a = (Int, Int)，它工作正常，但在规范中要求Point 是type Point a = (a, a)，这导致了我的错误。另一个问题是我不能更改函数类型，所以我不能按照建议添加(Ord a)。

有没有办法按第一个变量对元组列表进行排序而不会遇到错误？

Answer 1

在您的create 函数中，您使用sort :: Ord a => [a] -> [a]：

… = <b>sort</b> (((d p x), x) : ys)

这意味着我们正在排序的对象类型，在本例中为Tuple a，需要是Ord 类型类的实例。一个 2 元组是 Ord 类型类的一个实例，如果项目的两个类型也是 Ord 的实例，那么在这种情况下是 Double 和 Point a。因为Point a 也是一个二元组，但是是两个as，因此这意味着Tuple a 是Ord 的一个实例，如果a 是Ord 的一个实例。因此，您应该添加一个类型约束：

create :: Ord a => Metric a -> Point a -> [Point a] ->  [Tuple a] -> [Tuple a]
create d p (x:xs) ys | length xs == 0 = sort(((d p x), x) : ys)
                     | otherwise      = create d p xs (((d p x), x) : ys)

create 函数利用了一些反模式，例如使用 length，这需要线性时间。实际上，您可以将其重写为对映射进行排序：

create :: Ord a => Metric a -> Point a -> [Point a] -> [Tuple a]
create d p = sort . map f
    where f x = (d p x, x)

这删除了ys 参数，这里似乎只用作累加器。

如果您只想对 2 元组的第一项进行排序，可以使用 sortOn :: Ord b => (a -> b) -> [a] -> [a]：

create :: Metric a -> Point a -> [Point a] -> [Tuple a]
create d p = sortOn fst . map f
    where f x = (d p x, x)