我想知道您是否有在 mma 中显示循环内图的好方法。通常Plot函数的输出是不显示的，例如下面的代码：
For[i = 1, i <= 10, i++, Plot[Sin[i*x], {x, -Pi, Pi}]]
感谢您的帮助。
编辑
关于我的previous question，我已经有了 For 循环，例如，像这样的For[i = 1, i <= 10, i++, Plot[Sin[i*x], {x, -Pi, Pi}]]。鉴于这一事实，我想在 For 循环中添加类似“按任意键继续...”的内容，然后在每次按任意随机键时刷新绘图。谁能给出完整的工作代码？
【问题讨论】：
只需使用Print:
For[i = 1, i <= 10, i++, Plot[Sin[i*x], {x, -Pi, Pi}] // Print]
或Monitor：
Monitor[For[i = 1, i <= 10, i++, p = Plot[Sin[i*x], {x, -Pi, Pi}];
Pause[0.5]], p]
（这里使用暂停来给一些时间来查看情节；这里的循环非常快。如果需要，请删除）
编辑
根据要求，由鼠标控制的版本点击图表（按键需要图表获得焦点，因此您仍需要点击）
Monitor[For[i = 1, i <= 10, , p = Plot[Sin[i*x], {x, -Pi, Pi}]],
EventHandler[p, {"MouseDown" :> i++}]]
这是一种非常愚蠢的方法。循环不断地重绘绘图。所以，一个稍微（但仍然丑陋）的版本可能是：
s = True;
Monitor[
For[i = 1, i <= 10, ,
If[s,
(* Put main loop body here*)
p = Plot[Sin[i*x], {x, -Pi, Pi}]
(* end of main body *) ;
s = False (* prevents continuous re-evaluating main body *)
]
]
, EventHandler[p, {"MouseDown" :> (i++; s = True)}]
]
【讨论】：
PrintTemporary，它的作用类似于Print，但返回一个NotebookInterfaceObject，你可以在同一个评估中传递给NotebookDelete，删除单元格。避免使用SelectionMove。
只返回一个绘图列表，而不是使用For 循环：
Table[Plot[Sin[i*x], {x, -Pi, Pi}], {i, 1, 10}]
如果您希望将它们全部连接为一个情节，Show[listOfPlots] 是一种方法：
Show[Table[Plot[Sin[i*x], {x, -Pi, Pi}], {i, 1, 10}]]
更新
这是使用Dynamic 和EventHandler 的一种简单方法：
DynamicModule[{i = 1},
EventHandler[Dynamic[Plot[Sin[i*x], {x, -Pi, Pi}]],
{"KeyDown" :> i++}
]
这是一个用Animate 制作的稍微花哨的界面：
Animate[Plot[Sin[i*x], {x, -Pi, Pi}], {i, 1, 10, 1}, AnimationRunning -> False]
【讨论】：
Animate 和Manipulate。
如果你真的想让用户在 Plots 之间按下一个键，最简单的方法可能是
For[i = 1, i <= 10, i++,
If[!ChoiceDialog[Plot[Sin[i*x], {x, -Pi, Pi}],
WindowTitle -> "Plot #" <> ToString[i]
<> ": Press OK or Enter to continue"],
Abort[]]]
【讨论】：